Round Top3

[Ricardo01]

hello can anyone do me or if there is a TOP 3 DAMAGE plugin.

that shows the 3 that did the most damage and put that he did the most obvious damage in the top1

I leave you an example: https://prnt.sc/tkywax

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>

#if !defined MAX_PLAYERS
const MAX_PLAYERS = 32
#endif

#if !defined MAX_NAME_LENGTH
const MAX_NAME_LENGTH = 32
#endif

#define HUDMSG_COLOR 255, 255, 255
#define HUDMSG_POSITION -1.0, 0.7
#define HUDMSG_DURATION 5.0
#define HUDMSG_PLAYERS 3

new Float:g_fDamage[MAX_PLAYERS + 1], g_iFrags[MAX_PLAYERS + 1]

public plugin_init()
{
	register_plugin("Top Damage HUD", "1.1", "OciXCrom")
	RegisterHam(Ham_TakeDamage, "player", "OnTakeDamage", 1)
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	register_logevent("OnRoundEnd", 2, "1=Round_End")
}

public OnTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(iAttacker != iVictim && is_user_connected(iAttacker))
	{
		g_iFrags[iAttacker]++
		g_fDamage[iAttacker] += fDamage
	}
}

public OnRoundStart()
{
	arrayset(g_iFrags, 0, sizeof(g_iFrags))
	arrayset(g_fDamage, 0.0, sizeof(g_fDamage))
}

public OnRoundEnd()
{
	new iPlayers[MAX_PLAYERS], iPnum
	get_players(iPlayers, iPnum)

	SortCustom1D(iPlayers, sizeof(iPlayers), "SortPlayersByDamage")

	new szMessage[256], iNum = min(iPnum, HUDMSG_PLAYERS)
	szMessage = "[Top damagers for this round]^n^n"

	for(new i, iPlayer, szName[MAX_NAME_LENGTH]; i < iNum; i++)
	{
		iPlayer = iPlayers[i]
		get_user_name(iPlayer, szName, charsmax(szName))
		format(szMessage, charsmax(szMessage), "%s%i. %s - %.0f damage (%i kills)^n", szMessage, i + 1, szName, g_fDamage[iPlayer], g_iFrags[iPlayer])
	}

	set_hudmessage(HUDMSG_COLOR, HUDMSG_POSITION, .holdtime = HUDMSG_DURATION)
	show_hudmessage(0, szMessage)
}

public SortPlayersByDamage(id1, id2)
{
	return floatround(g_fDamage[id2] - g_fDamage[id1], floatround_floor)
}

[Ricardo01]

It works fine but I would like the name to come out one below the other, not next to each other.

1st Pepe leaves - 200 Damage - 2nd Jose 100 damage

and i want it to come out
1st Pepe - 200 damage
2nd Jose - 100 damage
3rd Louis - 50

[OciXCrom]

Edited.

[Ricardo01]

damage buggy bone continues to count and I want the round you made in round to count and restart, can you add next to the damage (elimination: 3) how much did you eliminate in that same round?

[OciXCrom]

Edited.

[Ricardo01]

AMX Mod X Compiler 1.9.0.5271
Copyright (c) 1997-2006 ITB CompuPhase
Copyright (c) 2004-2013 AMX Mod X Team

Error: Invalid function or declaration on line 68
Error: Invalid function or declaration on line 70
Error: Symbol already defined: "set_hudmessage" on line 77
Error: Symbol already defined: "SortPlayersByDamage" on line 82
Warning: Symbol is never used: "iNum" on line 68
Warning: Symbol is never used: "szMessage" on line 67

4 Errors.
Could not locate output file C:\Users\Matias\Desktop\ElMejorRound.amx (compile failed).

[atmax]

You are using another plugin this one doesn't have 70 lines?

[Ricardo01]

bad mine, I had copied everything wrong excuse me

[Ricardo01]

the same is still banned as much as kill and sometimes does not count them: V