set_user_noclip • прави играча способен да минава през стени

Библиотеката съдържа 22 natives и 0 forwards и 0 stocks.
Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

set_user_noclip • прави играча способен да минава през стени

Мнение от OciXCrom » 08 Окт 2016, 15:00

fun.incset_user_noclip(id, noclip = 0)

index: ID-то на играча
noclip: 1 е включено; 0 = изключено.

Връща: нищо
Функцията служи за да направите играча способен да минава през стени, т.е. да активирате noclip.

Примерен плъгин №1: Активиране на noclip чрез използване на командата /noclip.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Activate Noclip"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "OciXCrom"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say /noclip", "cmdNoclip")
    register_clcmd("say_team /noclip", "cmdNoclip")
}

public cmdNoclip(id)
{
    set_user_noclip(id, 1)
    client_print(id, print_chat, "* Uspeshno aktivira noclip!")
    return PLUGIN_HANDLED
}  
Примерен плъгин №2: Автоматизирано включване и изключване на noclip чрез използване на командата /noclip.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Toggle Noclip"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "OciXCrom"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say /noclip", "cmdNoclip")
    register_clcmd("say_team /noclip", "cmdNoclip")
}

public cmdNoclip(id)
{
    new bool:blNoclip = get_user_noclip(id) ? true : false
    set_user_noclip(id, blNoclip ? 0 : 1)
    client_print(id, print_chat, "* Noclip rejimut e: %s", blNoclip ? "IZKLIUCHEN" : "VKLIUCHEN")
    return PLUGIN_HANDLED
}  
Примерен плъгин №3: Автоматично включване на noclip за всички играчи и изключване чрез използване на командите /noclip on и /noclip off.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>

#define PLUGIN_NAME "Toggle Noclip for All"
#define PLUGIN_VERSION "1.0"
#define PLUGIN_AUTHOR "OciXCrom"

public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR)
    register_clcmd("say", "hookSay")
    register_clcmd("say_team", "hookSay")
}

public hookSay(id)
{
    new szSay[11], szCommand[7], szArg[3]
    read_args(szSay, charsmax(szSay))
    remove_quotes(szSay)
    
    parse(szSay, szCommand, charsmax(szCommand), szArg, charsmax(szArg))
    
    if(!equal(szCommand, "/noclip"))
        return PLUGIN_CONTINUE
        
    new iSetting = szArg[1] == 'n' ? 1 : 0
    
    new iPlayers[32], iPnum
    get_players(iPlayers, iPnum, "a")
    
    for(new i; i < iPnum; i++)
        set_user_noclip(iPlayers[i], iSetting)
    
    client_print(id, print_chat, "* Noclip rejimut e: %s", iSetting ? "VKLIUCHEN" : "IZKLIUCHEN")
    return PLUGIN_HANDLED
}  

Обратно към “fun.inc”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 9 госта