редактиране на плъгин за вип

[viewsonic]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define Plugin "ViP Plugin"
#define Version "1.0"
#define Author "TSK"

public plugin_init(){
 register_plugin(Plugin, Version, Author)
 RegisterHam(Ham_Spawn, "player", "FwdHamPlayerSpawn", true)
}

public FwdHamPlayerSpawn(id)
 set_task(1.0, "FwdHamPlayerSpawn2", id)

public FwdHamPlayerSpawn2(id){
 if(has_flag(id, "p") && is_user_alive(id))
 {
  set_user_health(id, 150)
  give_item(id, "weapon_awp")
  give_item(id, "weapon_hegrenade")
  //give_item(id, "weapon_flashbang"), cs_set_user_bpammo(id, CSW_FLASHBANG, 2)
 }
}

1.ако е възможно has_flag опцията да се запази
2.да има таб вип за CT и T отборите
3.set_user_health опцията и тя да се запази , HP 130
4.гранатите и флашбанга да се махнат
5.да се регенерира по 30 хп ако е възможно със опция както при set_user_health
6.може и нещо да препоръчате като допълнителна екстра

[RideeR ;]]

Направи кода в

Код за потвърждение: Избери целия код

такъв

формат и ще ти го направя.

[viewsonic]

готово

[OciXCrom]

Оправи заглавието на темата!

[viewsonic]

готово Oci

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define VIP_HEALTH 130
#define HEALTH_REGEN 30
#define HEALTH_REGEN_FREQ 1.0

#if defined client_disconnected
	#define client_disconnect client_disconnected
#endif

enum
{
	SCOREATTRIB_ARG_PLAYERID = 1,
	SCOREATTRIB_ARG_FLAGS
}

enum (<<= 1)
{
	SCOREATTRIB_FLAG_NONE = 0,
	SCOREATTRIB_FLAG_DEAD = 1,
	SCOREATTRIB_FLAG_BOMB,
	SCOREATTRIB_FLAG_VIP
}

/*15.да се регенерира по 30 хп ако е възможно със опция както при set_user_health*/

public plugin_init()
{
	register_plugin("Simple VIP Plugin", "1.0", "OciXCrom")
	register_message(get_user_msgid("ScoreAttrib"), "OnScoreAttrib")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public client_putinserver(id)
{
	if(is_user_vip(id))
		set_task(HEALTH_REGEN_FREQ, "RegenerateHealth", id)
}

public client_disconnect(id)
	remove_task(id)

public RegenerateHealth(id)
{
	new iHealth = get_user_health(id)

	if(iHealth < VIP_HEALTH)
		set_user_health(id, clamp(iHealth + HEALTH_REGEN, .max = VIP_HEALTH))
}

public OnScoreAttrib(iMsgId, iDest, iReceiver)
{
	if(is_user_vip(get_msg_arg_int(SCOREATTRIB_ARG_PLAYERID)))
		set_msg_arg_int(SCOREATTRIB_ARG_FLAGS, ARG_BYTE, SCOREATTRIB_FLAG_VIP)
}

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id) || !is_user_vip(id))
		return

	set_user_health(id, 150)
	give_item(id, "weapon_awp")
	cs_set_user_bpammo(id, CSW_AWP, 30)
}

bool:is_user_vip(id)
	return bool:(get_user_flags(id) & ADMIN_LEVEL_D)

[viewsonic]

вип флага от къде мога да го сменям ?

[ElitePower]

вип флага от къде мога да го сменям ?

return bool:(get_user_flags(id) & ADMIN_LEVEL_D) дано да не съм те заблудил

[viewsonic]

проблем:
1. не дава авп
2.ХП то не е 130 а 150 въпреки че е коригирано на 130
иначе вип таб има !

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define VIP_FLAG ADMIN_LEVEL_D
#define VIP_HEALTH 130
#define HEALTH_REGEN 30
#define HEALTH_REGEN_FREQ 1.0
#define SPAWN_DELAY 1.0

#if defined client_disconnected
	#define client_disconnect client_disconnected
#endif

enum
{
	SCOREATTRIB_ARG_PLAYERID = 1,
	SCOREATTRIB_ARG_FLAGS
}

enum (<<= 1)
{
	SCOREATTRIB_FLAG_NONE = 0,
	SCOREATTRIB_FLAG_DEAD = 1,
	SCOREATTRIB_FLAG_BOMB,
	SCOREATTRIB_FLAG_VIP
}

public plugin_init()
{
	register_plugin("Simple VIP Plugin", "1.0", "OciXCrom")
	register_message(get_user_msgid("ScoreAttrib"), "OnScoreAttrib")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}

public client_putinserver(id)
{
	if(is_user_vip(id))
		set_task(HEALTH_REGEN_FREQ, "RegenerateHealth", id)
}

public client_disconnect(id)
	remove_task(id)

public RegenerateHealth(id)
{
	new iHealth = get_user_health(id)

	if(iHealth < VIP_HEALTH)
		set_user_health(id, clamp(iHealth + HEALTH_REGEN, .max = VIP_HEALTH))
}

public OnScoreAttrib(iMsgId, iDest, iReceiver)
{
	if(is_user_vip(get_msg_arg_int(SCOREATTRIB_ARG_PLAYERID)))
		set_msg_arg_int(SCOREATTRIB_ARG_FLAGS, ARG_BYTE, SCOREATTRIB_FLAG_VIP)
}

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id) || !is_user_vip(id))
		return

	set_task(SPAWN_DELAY, "GiveStuff", id)
}

public GiveStuff(id)
{
	if(!is_user_alive(id))
		return

	set_user_health(id, VIP_HEALTH)
	give_item(id, "weapon_awp")
	cs_set_user_bpammo(id, CSW_AWP, 30)
}

bool:is_user_vip(id)
	return bool:(get_user_flags(id) & VIP_FLAG)