Sreen Fade - увеличаване на яркост

[PlayFear]

Ако някой може да ми редактира screen fade да премига с по ярък цвят от нормалното.

Код за потвърждение: Избери целия код

/*
*   http://games.qwerty.ru
*
*	AmxModX
*   Vampire plugin
*    by Shalfey
*
*   CVars
*   amx_vampire_hp - hp add for kill
*   amx_vampire_hp_hs - hp add for kill in head
*   amx_vampire_max_hp - max player hp
*
*   Players gets HP for kills.
*/
#include <amxmodx>
#include <fun>

#define PLUGIN_VERSION "1.0c"

new health_add
new health_hs_add
new health_max

new nKiller
new nKiller_hp
new nHp_add
new nHp_max

public plugin_init()
{
   register_plugin("Vampire", PLUGIN_VERSION, "Shalfey")

   health_add = register_cvar("amx_vampire_hp", "15")
   health_hs_add = register_cvar("amx_vampire_hp_hs", "40")
   health_max = register_cvar("amx_vampire_max_hp", "100")

   register_event("DeathMsg", "hook_death", "a", "1>0") 	
}

public hook_death()
{
   // Killer id
   nKiller = read_data(1)

   if ( (read_data(3) == 1) && (read_data(5) == 0) )
   {
      nHp_add = get_pcvar_num (health_hs_add)
   }
   else
      nHp_add = get_pcvar_num (health_add)

   nHp_max = get_pcvar_num (health_max)

   // Updating Killer HP
   nKiller_hp = get_user_health(nKiller)
   nKiller_hp += nHp_add

   // Maximum HP check
   if (nKiller_hp > nHp_max) nKiller_hp = nHp_max

   set_user_health(nKiller, nKiller_hp)

   // Hud message "Healed +15/+40 hp"
   set_hudmessage(0, 255, 0, -1.0, 0.15, 0, 1.0, 1.0, 0.1, 0.1, -1)
   show_hudmessage(nKiller, "Бонус +%d hp", nHp_add)

   // Screen fading
   message_begin(MSG_ONE, get_user_msgid("ScreenFade"), {0,0,0}, nKiller)
   write_short(1<<10)
   write_short(1<<10)
   write_short(0x0000)
   write_byte(0)
   write_byte(0)
   write_byte(200)
   write_byte(75)
   message_end()
   
} 

[OciXCrom]

Слагай по-свестни заглавия и гледай къде си пускаш темите!!!

В края на кода има write_byte(75).
Промени 75 на колкото искаш. Максимумът е 255 (най-ярко).

[PlayFear]

Благодаря, ще пробвам.

Може ли да го направиш като убиеш Т да премига в синио като убиеш цт в червено.

[OciXCrom]

С този ужасен код няма нищо да правя. Ползвай това:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>

#define HUD_ENABLED
#define HUD_COLOR 0, 255, 0
#define HUD_POSITION -1.0, 0.15
#define HUD_DURATION 1.5

#define SCREENFADE_ENABLED
#define SCREENFADE_COLOR_R 0
#define SCREENFADE_COLOR_G 0
#define SCREENFADE_COLOR_B 200
#define SCREENFADE_COLOR_A 75

enum _:Cvars
{
	amx_vampire_hp,
	amx_vampire_hp_hs,
	amx_vampire_max_hp
}

new g_eCvars[Cvars]

#if defined HUD_ENABLED
new g_iObject
#endif

#if defined SCREENFADE_ENABLED
new g_iScreenFade
#endif

public plugin_init()
{
	register_plugin("Vampire", "1.0", "OciXCrom")
	register_event("DeathMsg", "OnPlayerKilled", "a")
	g_eCvars[amx_vampire_hp] = register_cvar("amx_vampire_hp", "15")
	g_eCvars[amx_vampire_hp_hs] = register_cvar("amx_vampire_hp_hs", "40")
	g_eCvars[amx_vampire_max_hp] = register_cvar("amx_vampire_max_hp", "100")

	#if defined HUD_ENABLED
	g_iObject = CreateHudSyncObj()
	#endif

	#if defined SCREENFADE_ENABLED
	g_iScreenFade = get_user_msgid("ScreenFade")
	#endif
}

public OnPlayerKilled()
{
	new iAttacker = read_data(1), iVictim = read_data(2)
	
	if(!is_user_connected(iAttacker) || iAttacker == iVictim)
		return

	new iHealth = get_user_health(iAttacker), iMax = get_pcvar_num(g_eCvars[amx_vampire_max_hp])

	if(iHealth >= iMax)
		return

	new iAdd = read_data(3) ? get_pcvar_num(g_eCvars[amx_vampire_hp_hs]) : get_pcvar_num(g_eCvars[amx_vampire_hp])
	set_user_health(iAttacker, clamp(iHealth + iAdd, .max = iMax))

	#if defined HUD_ENABLED
	set_hudmessage(HUD_COLOR, HUD_POSITION, .holdtime = HUD_DURATION)
	ShowSyncHudMsg(iAttacker, g_iObject, "Бонус +%i HP", iAdd)
	#endif

	#if defined SCREENFADE_ENABLED
	message_begin(MSG_ONE, g_iScreenFade, {0, 0, 0}, iAttacker)
	write_short(1<<10)
	write_short(1<<10)
	write_short(0x0000)
	write_byte(SCREENFADE_COLOR_R)
	write_byte(SCREENFADE_COLOR_G)
	write_byte(SCREENFADE_COLOR_B)
	write_byte(SCREENFADE_COLOR_A)
	message_end()
	#endif
}