[Изработка на плъгин] Когато стрелям някой да свети в червено

[g0gIch]

Може ли това да стане?

[OciXCrom]

Само ти да виждаш червеното или всички? Тоест играчът да става червен когато получава щета?

[g0gIch]

Когато нанасям щета на някой, цветът в който ще бъде glow-нат(така да се каже) играча да се вижда от всеки.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>
#include <hamsandwich>

#define GLOW_DURATION 1.0
#define GLOW_COLOR 255, 0, 0
#define GLOW_BRIGHTNESS 50

public plugin_init()
{
	register_plugin("Glow on Damage", "1.0", "OciXCrom")
	RegisterHam(Ham_TakeDamage, "player", "OnTakeDamage", 1)
}

public OnTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!is_user_alive(iVictim))
		return
	
	set_user_rendering(iVictim, kRenderFxGlowShell, GLOW_COLOR, kRenderNormal, GLOW_BRIGHTNESS)
	set_task(GLOW_DURATION, "RemoveGlow", iVictim)
}

public RemoveGlow(id)
{
	if(is_user_connected(id))
		set_user_rendering(id)
}

[g0gIch]

Благодаря, работи. А ще може ли да се направи команда за включване/изключване на плъгина и вместо всеки път да променям от кода стойностите да се направи cvar?

[illusion]

Това с cvar-овете ти го направих, не съм го тествал:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>
#include <hamsandwich>

new GlowDuration, GlowColor, GlowBrightness;

public plugin_init()
{
	register_plugin("Glow on Damage", "1.0", "OciXCrom")
	RegisterHam(Ham_TakeDamage, "player", "OnTakeDamage", 1)
	GlowDuration = register_cvar("amx_god_duration", "1.0")
	GlowColor = register_cvar("amx_god_color", "255 0 0")
	GlowBrightness = register_cvar("amx_god_brightness", "50")
}

public OnTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!is_user_alive(iVictim))
		return
	
	set_user_rendering(iVictim, kRenderFxGlowShell, get_pcvar_num(GlowColor), kRenderNormal, get_pcvar_num(GlowBrightness))
	set_task(get_pcvar_num(GlowDuration), "RemoveGlow", iVictim)
}

public RemoveGlow(id)
{
	if(is_user_connected(id))
		set_user_rendering(id)
}

GlowDuration = register_cvar("amx_god_duration", "1.0")
GlowColor = register_cvar("amx_god_color", "255 0 0")
GlowBrightness = register_cvar("amx_god_brightness", "50")

[OciXCrom]

Няма да работи, тъй като с get_pcvar_num не можеш да вземеш стойност от вида "255 0 0" - можеш само едно число да вземеш. За плаващи числа трябва да ползваш get_pcvar_float. Ето поправен код - направих стойностите на кваровете да се проверяват в началото на рунда, вместо при всяко получаване щета:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fun>
#include <hamsandwich>

new Float:g_fDuration, bool:g_bEnabled, g_iColor[3], g_iBrightness
new GlowDuration, GlowColor, GlowBrightness, GlowEnabled

public plugin_init()
{
	register_plugin("Glow on Damage", "1.0", "OciXCrom")
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	RegisterHam(Ham_TakeDamage, "player", "OnTakeDamage", 1)
	GlowDuration = register_cvar("amx_glow_duration", "1.0")
	GlowColor = register_cvar("amx_glow_color", "255 0 0")
	GlowBrightness = register_cvar("amx_glow_brightness", "50")
	GlowEnabled = register_cvar("amx_glow_enabled", "1")
}

public plugin_cfg()
	OnRoundStart()

public OnRoundStart()
{
	g_fDuration = get_pcvar_float(GlowDuration)
	g_bEnabled = bool:get_pcvar_num(GlowEnabled)
	g_iBrightness = get_pcvar_num(GlowBrightness)

	new szCvar[12], szColor[3][3]
	get_pcvar_string(GlowColor, szCvar, charsmax(szCvar))
	parse(szCvar, szColor[0], charsmax(szColor[]), szColor[1], charsmax(szColor[]), szColor[2], charsmax(szColor[]))

	for(new i; i < sizeof(szColor[]); i++)
		g_iColor[i] = str_to_num(szColor[i])
}

public OnTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!g_bEnabled || !is_user_alive(iVictim))
		return
	
	set_user_rendering(iVictim, kRenderFxGlowShell, g_iColor[0], g_iColor[1], g_iColor[2], kRenderNormal, g_iBrightness)
	set_task(g_fDuration, "RemoveGlow", iVictim)
}

public RemoveGlow(id)
{
	if(is_user_connected(id))
		set_user_rendering(id)
}