/Shop за CT и T покупка с пари.
-
OciXCrom
Извън линия - Администратор
- Мнения: 7206
- Регистриран на: 06 Окт 2016, 19:20
- Местоположение: /resetscore
- Се отблагодари: 117 пъти
- Получена благодарност: 1295 пъти
- Обратна връзка:
/Shop за CT и T покупка с пари.
Защо просто не тестваш или погледнеш кода? Както виждаш има настройка за кой отбор да е всеки един итем.
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Ок ще го тествам малко по-късно а за 2-пъти повече щети има ли за сяко оръжие от стандартното или аз не го виждам в кода.
Добавено преди 7 минути 38 секунди:
Лека корекция ще направиш ли искам когато вземат сяко 1 от оръжията да им дава допълнително кръв на сяко 1 убийство ето пример.
CT да им излиза.
1.Gold_Deagle=cost 5000$ +5 кръв
2.Gold_M4A1=cost 10000$ + 10 кръв
3.Gold_AWP=cost 16000$ + 20 кръв
T да им излиза.
1.Gold_Glock=cost 5000$ +5 кръв
2.Gold_AK47=cost 10000$ + 10 кръв
3.Gold_AWP=cost 16000$ + 20 кръв
Само тази добавка и друго няма да има.
Добавено преди 7 минути 38 секунди:
Лека корекция ще направиш ли искам когато вземат сяко 1 от оръжията да им дава допълнително кръв на сяко 1 убийство ето пример.
CT да им излиза.
1.Gold_Deagle=cost 5000$ +5 кръв
2.Gold_M4A1=cost 10000$ + 10 кръв
3.Gold_AWP=cost 16000$ + 20 кръв
T да им излиза.
1.Gold_Glock=cost 5000$ +5 кръв
2.Gold_AK47=cost 10000$ + 10 кръв
3.Gold_AWP=cost 16000$ + 20 кръв
Само тази добавка и друго няма да има.
-
OciXCrom
Извън линия - Администратор
- Мнения: 7206
- Регистриран на: 06 Окт 2016, 19:20
- Местоположение: /resetscore
- Се отблагодари: 117 пъти
- Получена благодарност: 1295 пъти
- Обратна връзка:
/Shop за CT и T покупка с пари.
Код за потвърждение: Избери целия код
#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
//#define USING_REAPI
#define REPLACE_OLD_WEAPONS
#if defined USING_REAPI
#include <reapi>
#else
#if defined REPLACE_OLD_WEAPONS
#include <stripweapons>
#endif
#endif
#define PLUGIN_VERSION "1.0"
#define SOUND_BUY "items/gunpickup2.wav"
#define NO_WEAPON -1
enum _:ItemInfo
{
Name[32],
Price,
Weapon[16],
Ammo,
Csw,
VModel[32],
PModel[32],
CsTeams:Team,
Health
}
new const g_eItems[][ItemInfo] =
{
/* "Name", Price, "weapon_id", Bullets, CSW_ID, "v_model", "p_model", "team" */
{ "Golden Deagle", 5000, "weapon_deagle", 35, CSW_DEAGLE, "models/v_deagle.mdl", "models/p_deagle.mdl", CS_TEAM_CT, 5 },
{ "Golden M4A1", 10000, "weapon_m4a1", 90, CSW_M4A1, "models/v_m4a1.mdl", "models/p_m4a1.mdl", CS_TEAM_CT, 10 },
{ "Golden Glock", 5000, "weapon_glock18", 30, CSW_GLOCK18, "models/v_glock18.mdl", "models/p_glock18.mdl", CS_TEAM_T, 5 },
{ "Golden AK47", 10000, "weapon_ak47", 90, CSW_AWP, "models/v_ak47.mdl", "models/p_ak47.mdl", CS_TEAM_T, 10 },
{ "Golden AWP", 16000, "weapon_awp", 30, CSW_AWP, "models/v_awp.mdl", "models/p_awp.mdl", CS_TEAM_CT|CS_TEAM_T, 20 }
}
new g_iWeapon[33]
public plugin_init()
{
register_plugin("Golden Shop", PLUGIN_VERSION, "OciXCrom")
register_cvar("CRXGoldenShop", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
register_event("CurWeapon", "OnChangeWeapon", "be", "1=1")
register_event("DeathMsg", "OnPlayerKilled", "a")
RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
register_clcmd("say /gold", "Cmd_Shop")
register_clcmd("say_team /gold", "Cmd_Shop")
CC_SetPrefix("[&x04GOLD&x01]")
}
public plugin_precache()
{
precache_sound(SOUND_BUY)
for(new i; i < sizeof(g_eItems); i++)
{
if(g_eItems[i][VModel][0])
precache_model(g_eItems[i][VModel])
if(g_eItems[i][PModel][0])
precache_model(g_eItems[i][PModel])
}
}
public client_putinserver(id)
g_iWeapon[id] = NO_WEAPON
public OnPlayerSpawn(id)
g_iWeapon[id] = NO_WEAPON
public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
if(g_iWeapon[iAttacker] != NO_WEAPON)
SetHamParamFloat(4, fDamage * 2)
}
public OnPlayerKilled()
{
new iAttacker = read_data(1), iVictim = read_data(2)
if(is_user_connected(iAttacker) && is_user_connected(iVictim) && g_iWeapon[iAttacker] != NO_WEAPON)
set_user_health(iAttacker, get_user_health(iAttacker) + g_eItems[g_iWeapon[iAttacker]][Health])
}
public OnChangeWeapon(id)
{
if(g_iWeapon[id] == NO_WEAPON || read_data(2) != g_eItems[g_iWeapon[id]][Csw])
return
if(g_eItems[g_iWeapon[id]][VModel][0])
set_pev(id, pev_viewmodel2, g_eItems[g_iWeapon[id]][VModel])
if(g_eItems[g_iWeapon[id]][PModel][0])
set_pev(id, pev_weaponmodel2, g_eItems[g_iWeapon[id]][PModel])
}
public Cmd_Shop(id)
{
if(!is_user_alive(id))
CC_SendMessage(id, "You need to be alive.")
else
{
new iMenu = menu_create("\rGold Shop", "Shop_Handler")
new szItem[64], iMoney = cs_get_user_money(id)
for(new CsTeams:iTeam = cs_get_user_team(id), i; i < sizeof(g_eItems); i++)
{
if(g_eItems[i][Team] & iTeam)
{
if(g_iWeapon[id] == i)
formatex(szItem, charsmax(szItem), "\d%s \y[OWNED]", g_eItems[i][Name])
else
formatex(szItem, charsmax(szItem), "%s%s \r[%i$]", iMoney >= g_eItems[i][Price] ? "\w" : "\d", g_eItems[i][Name], g_eItems[i][Price])
menu_additem(iMenu, szItem)
}
}
menu_display(id, iMenu)
}
return PLUGIN_HANDLED
}
public Shop_Handler(id, iMenu, iItem)
{
if(iItem != MENU_EXIT && is_user_alive(id))
{
if(g_iWeapon[id] == iItem)
CC_SendMessage(id, "You already have this item.")
else
{
new iMoney = cs_get_user_money(id)
if(iMoney < g_eItems[iItem][Price])
CC_SendMessage(id, "You don't have enough money to purchase this item.")
else
{
cs_set_user_money(id, iMoney - g_eItems[iItem][Price])
CC_SendMessage(id, "You have bought ^3%s ^1for ^4%i$", g_eItems[iItem][Name], g_eItems[iItem][Price])
emit_sound(id, CHAN_ITEM, SOUND_BUY, 1.0, ATTN_NORM, 0, PITCH_NORM)
g_iWeapon[id] = iItem
#if defined USING_REAPI
#if defined REPLACE_OLD_WEAPONS
rg_give_item(id, g_eItems[iItem][Weapon], GT_REPLACE)
#else
rg_give_item(id, g_eItems[iItem][Weapon], GT_APPEND)
#endif
#else
#if defined REPLACE_OLD_WEAPONS
StripWeapons(id, Primary)
#endif
give_item(id, g_eItems[iItem][Weapon])
#endif
cs_set_user_bpammo(id, g_eItems[iItem][Csw], g_eItems[iItem][Ammo])
OnChangeWeapon(id)
}
}
}
menu_destroy(iMenu)
return PLUGIN_HANDLED
}
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Благодаря ще го тествам довечера и ще пиша че в момента не съм на компа.
-
- Подобни теми
- Отговори
- Преглеждания
- Последно мнение
-
- 4 Отговори
- 1506 Преглеждания
-
Последно мнение от iv69
-
- 1 Отговори
- 1560 Преглеждания
-
Последно мнение от OciXCrom
-
- 0 Отговори
- 1260 Преглеждания
-
Последно мнение от Ivo951
-
- 34 Отговори
- 11934 Преглеждания
-
Последно мнение от Scorpions95
-
- 0 Отговори
- 1269 Преглеждания
-
Последно мнение от Scar
-
- 1 Отговори
- 1493 Преглеждания
-
Последно мнение от TheScale
-
- 0 Отговори
- 710 Преглеждания
-
Последно мнение от narkoman69
Кой е на линия
Потребители разглеждащи този форум: 0 регистрирани и 24 госта