/Shop за CT и T покупка с пари.
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Трябва ми /shop плъгин за CT и T. в 1 плъгин да е. Като всяко 1 оръжие да взима 2- пъти повече щети от стандартните.Без никакви админски права стандартен за 2-та отбора пишат /shop и ако имат достатъчно пари да си ги копуват.Моделите ще си ги сложа след това.Нищо друго излишно не искам ако има то ще пиша в темата като добавка за сега само това.
CT да им излиза.
1.Gold_Deagle=cost 5000$
2.Gold_M4A1=cost 10000$
3.Gold_AWP=cost 16000$
T да им излиза.
1.Gold_Glock=cost 5000$
2.Gold_AK47=cost 10000$
3.Gold_AWP=cost 16000$
CT да им излиза.
1.Gold_Deagle=cost 5000$
2.Gold_M4A1=cost 10000$
3.Gold_AWP=cost 16000$
T да им излиза.
1.Gold_Glock=cost 5000$
2.Gold_AK47=cost 10000$
3.Gold_AWP=cost 16000$
-
User12
Извън линия - Потребител
- Мнения: 321
- Регистриран на: 25 Яну 2018, 22:39
- Местоположение: Сливен
- Се отблагодари: 40 пъти
- Получена благодарност: 17 пъти
- Обратна връзка:
/Shop за CT и T покупка с пари.
Плъгина на OciXRoM не си ли го видял , мен ми харесва ако ти върши работа : OciXCrom's Custom Shop + API
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Да знам го но него бих го ползвал за CSDM за сега искам само този не искам с нищо друго излишно да има за това съм пуснал заявката.
-
deadlylord
Извън линия - Потребител
- Мнения: 572
- Регистриран на: 04 Апр 2017, 16:35
- Местоположение: Бургас, България
- Получена благодарност: 2 пъти
- Обратна връзка:
/Shop за CT и T покупка с пари.
Просто си ги вкарай в менюто OciXCrom's Custom Shop + API и спри всички ненужни за теб предмети, крома е обяснил как се правят златни оръжия(просто сменяш от ak47 на m4a1 или което ти е оръжието, а пък самата информация за оръжията можеш да видиш от тук)
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Не ми предлагайте нищо друго моля ви ако ще го прави някой да го направи ако не здраве да е.Хем виждате какво точно и само него искам вие ми предлагате нещо което ако исках до сега да бях го сложил и нямаше да пускам тази тема.
/Shop за CT и T покупка с пари.
Ем то пробвах се да ти го направя но нещо това с моделите не ми се получи както трябва
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Писах горе как го искам ако няма кой да го направи заключете темата.
-
OciXCrom
Извън линия - Администратор
- Мнения: 7206
- Регистриран на: 06 Окт 2016, 19:20
- Местоположение: /resetscore
- Се отблагодари: 117 пъти
- Получена благодарност: 1295 пъти
- Обратна връзка:
/Shop за CT и T покупка с пари.
Код за потвърждение: Избери целия код
#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
//#define USING_REAPI
#define REPLACE_OLD_WEAPONS
#if defined USING_REAPI
#include <reapi>
#else
#if defined REPLACE_OLD_WEAPONS
#include <stripweapons>
#endif
#endif
#define PLUGIN_VERSION "1.0"
#define SOUND_BUY "items/gunpickup2.wav"
#define NO_WEAPON -1
enum _:ItemInfo
{
Name[32],
Price,
Weapon[16],
Ammo,
Csw,
VModel[32],
PModel[32],
CsTeams:Team
}
new const g_eItems[][ItemInfo] =
{
/* "Name", Price, "weapon_id", Bullets, CSW_ID, "v_model", "p_model", "team" */
{ "Golden Deagle", 5000, "weapon_deagle", 35, CSW_DEAGLE, "models/v_deagle.mdl", "models/p_deagle.mdl", CS_TEAM_CT },
{ "Golden M4A1", 10000, "weapon_m4a1", 90, CSW_M4A1, "models/v_m4a1.mdl", "models/p_m4a1.mdl", CS_TEAM_CT },
{ "Golden Glock", 5000, "weapon_glock18", 30, CSW_GLOCK18, "models/v_glock18.mdl", "models/p_glock18.mdl", CS_TEAM_T },
{ "Golden AK47", 10000, "weapon_ak47", 90, CSW_AWP, "models/v_ak47.mdl", "models/p_ak47.mdl", CS_TEAM_T },
{ "Golden AWP", 16000, "weapon_awp", 30, CSW_AWP, "models/v_awp.mdl", "models/p_awp.mdl", CS_TEAM_CT|CS_TEAM_T }
}
new g_iWeapon[33]
public plugin_init()
{
register_plugin("Golden Shop", PLUGIN_VERSION, "OciXCrom")
register_cvar("CRXGoldenShop", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
register_event("CurWeapon", "OnChangeWeapon", "be", "1=1")
RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
register_clcmd("say /gold", "Cmd_Shop")
register_clcmd("say_team /gold", "Cmd_Shop")
CC_SetPrefix("[&x04GOLD&x01]")
}
public plugin_precache()
{
precache_sound(SOUND_BUY)
for(new i; i < sizeof(g_eItems); i++)
{
if(g_eItems[i][VModel][0])
precache_model(g_eItems[i][VModel])
if(g_eItems[i][PModel][0])
precache_model(g_eItems[i][PModel])
}
}
public client_putinserver(id)
g_iWeapon[id] = NO_WEAPON
public OnPlayerSpawn(id)
g_iWeapon[id] = NO_WEAPON
public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
if(g_iWeapon[iAttacker] != NO_WEAPON)
SetHamParamFloat(4, fDamage * 2)
}
public OnChangeWeapon(id)
{
if(g_iWeapon[id] == NO_WEAPON || read_data(2) != g_eItems[g_iWeapon[id]][Csw])
return
if(g_eItems[g_iWeapon[id]][VModel][0])
set_pev(id, pev_viewmodel2, g_eItems[g_iWeapon[id]][VModel])
if(g_eItems[g_iWeapon[id]][PModel][0])
set_pev(id, pev_weaponmodel2, g_eItems[g_iWeapon[id]][PModel])
}
public Cmd_Shop(id)
{
if(!is_user_alive(id))
CC_SendMessage(id, "You need to be alive.")
else
{
new iMenu = menu_create("\rGold Shop", "Shop_Handler")
new szItem[64], iMoney = cs_get_user_money(id)
for(new CsTeams:iTeam = cs_get_user_team(id), i; i < sizeof(g_eItems); i++)
{
if(g_eItems[i][Team] & iTeam)
{
if(g_iWeapon[id] == i)
formatex(szItem, charsmax(szItem), "\d%s \y[OWNED]", g_eItems[i][Name])
else
formatex(szItem, charsmax(szItem), "%s%s \r[%i$]", iMoney >= g_eItems[i][Price] ? "\w" : "\d", g_eItems[i][Name], g_eItems[i][Price])
menu_additem(iMenu, szItem)
}
}
menu_display(id, iMenu)
}
return PLUGIN_HANDLED
}
public Shop_Handler(id, iMenu, iItem)
{
if(iItem != MENU_EXIT && is_user_alive(id))
{
if(g_iWeapon[id] == iItem)
CC_SendMessage(id, "You already have this item.")
else
{
new iMoney = cs_get_user_money(id)
if(iMoney < g_eItems[iItem][Price])
CC_SendMessage(id, "You don't have enough money to purchase this item.")
else
{
cs_set_user_money(id, iMoney - g_eItems[iItem][Price])
CC_SendMessage(id, "You have bought ^3%s ^1for ^4%i$", g_eItems[iItem][Name], g_eItems[iItem][Price])
emit_sound(id, CHAN_ITEM, SOUND_BUY, 1.0, ATTN_NORM, 0, PITCH_NORM)
g_iWeapon[id] = iItem
#if defined USING_REAPI
#if defined REPLACE_OLD_WEAPONS
rg_give_item(id, g_eItems[iItem][Weapon], GT_REPLACE)
#else
rg_give_item(id, g_eItems[iItem][Weapon], GT_APPEND)
#endif
#else
#if defined REPLACE_OLD_WEAPONS
StripWeapons(id, Primary)
#endif
give_item(id, g_eItems[iItem][Weapon])
#endif
cs_set_user_bpammo(id, g_eItems[iItem][Csw], g_eItems[iItem][Ammo])
OnChangeWeapon(id)
}
}
}
menu_destroy(iMenu)
return PLUGIN_HANDLED
}
Ако даден модел няма p_ модел, оставяш полето празно ("").
Ако ползваш ReAPI & ReGameDLL, разкоментирай реда #define USING_REAPI.
Ако не искаш старите оръжия да се премахват, коментирай реда #define REPLACE_OLD_WEAPONS.
-
cgozzie
Извън линия - Потребител
- Мнения: 1319
- Регистриран на: 13 Окт 2016, 22:10
- Местоположение: Варна
- Се отблагодари: 245 пъти
- Получена благодарност: 43 пъти
/Shop за CT и T покупка с пари.
Извинявам се това 1 общо меню ли е за 2-та отбора ако е така не искам да е общо искам за секи отбор отделно ето така
T да им излиза.
1.Gold_Glock=cost 5000$
2.Gold_AK47=cost 10000$
3.Gold_AWP=cost 16000$
и за
CT да им излиза.
1.Gold_Deagle=cost 5000$
2.Gold_M4A1=cost 10000$
3.Gold_AWP=cost 16000$
Просто исках да е в 1 плъгин или трябва да са 2 незнам ти ще кажеш.
T да им излиза.
1.Gold_Glock=cost 5000$
2.Gold_AK47=cost 10000$
3.Gold_AWP=cost 16000$
и за
CT да им излиза.
1.Gold_Deagle=cost 5000$
2.Gold_M4A1=cost 10000$
3.Gold_AWP=cost 16000$
Просто исках да е в 1 плъгин или трябва да са 2 незнам ти ще кажеш.
-
- Подобни теми
- Отговори
- Преглеждания
- Последно мнение
-
- 4 Отговори
- 1506 Преглеждания
-
Последно мнение от iv69
-
- 1 Отговори
- 1559 Преглеждания
-
Последно мнение от OciXCrom
-
- 0 Отговори
- 1260 Преглеждания
-
Последно мнение от Ivo951
-
- 34 Отговори
- 11933 Преглеждания
-
Последно мнение от Scorpions95
-
- 0 Отговори
- 1269 Преглеждания
-
Последно мнение от Scar
-
- 1 Отговори
- 1492 Преглеждания
-
Последно мнение от TheScale
-
- 0 Отговори
- 706 Преглеждания
-
Последно мнение от narkoman69
Кой е на линия
Потребители разглеждащи този форум: 0 регистрирани и 21 госта