Намиране на плъгин за писане във админ чата!

[Lord]

Може ли някой да ми направи/намери плъгин като някой напише във чата нещо свързано със хак примерно да има ини файл със думи и да пише на админ чата примерно
админ има хак! и то автоматично да пише на админ чата но да не се вижда във нормалния чат!
Благодаря предварително

[[N]eXuS]

Щото админа не вижда чата

[OciXCrom]

Създаваш файл в amxmodx/configs с име SlqpiAdmini.ini и добавяш всяка дума на нов ред.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cromchat>

#define MAX_WORD_SIZE 32

new Array:g_aWords, g_iArraySize

public plugin_precache()
{
	register_plugin("Slqpi Admini", "1.0", "OciXCrom")
	register_clcmd("say", "Hook_Say")
	register_clcmd("say_team", "Hook_Say")
	g_aWords = ArrayCreate(MAX_WORD_SIZE)
	ReadFile()
}

public plugin_end()
	ArrayDestroy(g_aWords)
	
public Hook_Say(id)
{
	static szArgs[192]
	read_args(szArgs, charsmax(szArgs))
	remove_quotes(szArgs)
	
	if(szArgs[0])
	{
		static szWord[MAX_WORD_SIZE], bool:bMatch, i
		bMatch = false
		
		for(i = 0; i < g_iArraySize; i++)
		{
			ArrayGetString(g_aWords, i, szWord, charsmax(szWord))
			
			if(containi(szArgs, szWord) != -1)
			{
				bMatch = true
				break
			}
		}
		
		if(bMatch)
		{
			static szName[32], iPlayers[32], iPnum, iPlayer
			get_user_name(id, szName, charsmax(szName))
			get_players(iPlayers, iPnum)
			
			for(i = 0; i < iPnum; i++)
			{
				iPlayer = iPlayers[i]
				
				if(is_user_admin(iPlayer))
					CC_SendMessage(iPlayer, "&x04(ADMIN) %s : %s", szName, szArgs)
			}
		}
	}
}

ReadFile()
{
	new szConfigsName[256], szFilename[256]
	get_configsdir(szConfigsName, charsmax(szConfigsName))
	formatex(szFilename, charsmax(szFilename), "%s/SlqpiAdmini.ini", szConfigsName)
	new iFilePointer = fopen(szFilename, "rt")
	
	if(iFilePointer)
	{
		new szData[MAX_WORD_SIZE]
		
		while(!feof(iFilePointer))
		{
			fgets(iFilePointer, szData, charsmax(szData))
			trim(szData)
			
			if(szData[0] == EOS || szData[0] == ';')
				continue
				
			ArrayPushString(g_aWords, szData)
		}
		
		g_iArraySize = ArraySize(g_aWords)
		fclose(iFilePointer)
	}
}