Give Flags VIP when under Top3

[Infamous2018]

It looks that this plugin is configurated for 1.9 and higher. oxi or other one, can anyone make it for 1.8.3 ? i cant change to 1.9 .

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <csstats>

const IGNORE_FLAG = ADMIN_BAN
const Float:DELAY_ON_CONNECT = 0.3
const Float:DELAY_ON_MESSAGE = 5.0

enum _:Flags
{
	Rank,
	Flag[2]
}

new const g_eFlags[][Flags] =
{
	{ 3, "birt" }
}

new g_iFlag[33]

public plugin_init()
{
	register_plugin("Top Awards", "1.0", "OciXCrom")
	register_dictionary("topawards.txt")
	CC_SetPrefix("&x04[Top Awards]")
}

public client_putinserver(id)
{
	g_iFlag[id] = 0
	set_task(DELAY_ON_CONNECT, "check_flags", id)
}

public check_flags(id)
{
	if(!is_user_connected(id) || get_user_flags(id) & IGNORE_FLAG)
		return

	new iStats[8], iHits[8]
	get_user_stats(id, iStats, iHits)

	new iRank = iStats[7]

	for(new i; i < sizeof(g_eFlags); i++)
	{
		if(iRank <= g_eFlags[i][Rank])
		{
			g_iFlag[id] = i
			set_user_flags(id, read_flags(g_eFlags[i][Flag]))
			set_task(DELAY_ON_MESSAGE, "send_message", id)
			break
		}
	}
}

public send_message(id)
{
	if(!is_user_connected(id))
		return

	CC_SendMessage(id, "%L", id, "TOPAWARD_GET", g_eFlags[g_iFlag[id]][Flag], g_eFlags[g_iFlag[id]][Rank])
}

Код за потвърждение: Избери целия код

AMX Mod X Compiler 1.8.3-dev+5154
Copyright (c) 1997-2006 ITB CompuPhase
Copyright (c) 2004-2013 AMX Mod X Team

Warning: Length of initialler exceeds size of the enum field on line 17
Error: Initialization data exceeds declared size on line 17

1 Error.
(compile failed).

[Huehue]

Код за потвърждение: Избери целия код

enum _:Flags
{
	Rank,
	Flag[2]
}

->

Код за потвърждение: Избери целия код

enum _:Flags
{
	Rank,
	Flag[6]
}

[Infamous2018]

Thx ! will test this later.

[OciXCrom]

1.8.3 is no longer supported. You should update to the latest 1.9 version. 1.8.3 is just an older 1.9 build.

[Infamous2018]

The Plugin still dont work. First round u have flag "BIRTY" or about some seconds but when you got respawned after dead u have flag / So no Flag. Flags are removed. Any idea???

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <csstats>

const IGNORE_FLAG = ADMIN_BAN
const Float:DELAY_ON_CONNECT = 0.3
const Float:DELAY_ON_MESSAGE = 5.0

enum _:Flags
{
	Rank,
	Flag[6]
}

new const g_eFlags[][Flags] =
{
	{ 3, "birt" }
}

new g_iFlag[33]

public plugin_init()
{
	register_plugin("Top Awards", "1.0", "OciXCrom")
	register_dictionary("topawards.txt")
	CC_SetPrefix("&x04[Top Awards]")
}

public client_putinserver(id)
{
	g_iFlag[id] = 0
	set_task(DELAY_ON_CONNECT, "check_flags", id)
}

public check_flags(id)
{
	if(!is_user_connected(id) || get_user_flags(id) & IGNORE_FLAG)
		return

	new iStats[8], iHits[8]
	get_user_stats(id, iStats, iHits)

	new iRank = iStats[7]

	for(new i; i < sizeof(g_eFlags); i++)
	{
		if(iRank <= g_eFlags[i][Rank])
		{
			g_iFlag[id] = i
			set_user_flags(id, read_flags(g_eFlags[i][Flag]))
			set_task(DELAY_ON_MESSAGE, "send_message", id)
			break
		}
	}
}

public send_message(id)
{
	if(!is_user_connected(id))
		return

	CC_SendMessage(id, "%L", id, "TOPAWARD_GET", g_eFlags[g_iFlag[id]][Flag], g_eFlags[g_iFlag[id]][Rank])
}

[Infamous2018]

Thread can be closed. It was an Happy Hour Time VIP Plugin who did the Problem and removed the Flags. Now this Plugin is working.