request - sxe plugin, steam, no steam

[vini2001]

would like a plugin, when players type .sxe a list of online players appears and specifying each:

bob - (SXE)
luke - (NO SXE)
nesk - (STEAM)

[OciXCrom]

I don't think sXe has an API (.inc file) that we can use to check whether a player is using it or not. Do players with/without the anti-cheat have a tag in their name or something that we can detect using an AMXX plugin?

[vini2001]

if I'm not mistaken
with VALVE_0
without VALVE_1
STEAM STEAM_ID

[OciXCrom]

If that's the case, try:

Код за потвърждение: Избери целия код

#include <amxmodx>

#if !defined MAX_PLAYERS
	const MAX_PLAYERS = 32
#endif

#if !defined MAX_AUTHID_LENGTH
	const MAX_AUTHID_LENGTH = 64
#endif

enum
{
	AUTH_NONE,
	AUTH_STEAM,
	AUTH_NO_SXE,
	AUTH_SXE
}

new g_iAuthType[MAX_PLAYERS + 1]

public plugin_init()
{
	register_plugin("sXe List", "1.0", "OciXCrom")
	register_clcmd("say .sxe", "Cmd_ListPlayers")
	register_clcmd("say_team .sxe", "Cmd_ListPlayers")
}

public client_authorized(id)
{
	new szAuthId[MAX_AUTHID_LENGTH]
	get_user_authid(id, szAuthId, charsmax(szAuthId))

	switch(szAuthId[0])
	{
		case 'S': g_iAuthType[id] = AUTH_STEAM
		case 'V':
		{
			g_iAuthType[id] = szAuthId[8] == '0' ? AUTH_SXE : AUTH_NO_SXE
		}
		default: g_iAuthType[id] = AUTH_NONE
	}
}

public Cmd_ListPlayers(id)
{
	new iMenu = menu_create("Players List", "ListPlayers_Handler")

	new iPlayers[MAX_PLAYERS], iPnum
	get_players(iPlayers, iPnum)

	for(new szItem[50], iPlayer, i; i < iPnum; i++)
	{
		iPlayer = iPlayers[i]
		get_user_name(iPlayer, szItem, charsmax(szItem))

		switch(g_iAuthType[iPlayer])
		{
			case AUTH_STEAM: add(szItem, charsmax(szItem), "\y [STEAM]")
			case AUTH_NO_SXE: add(szItem, charsmax(szItem), "\d [no sXe]")
			case AUTH_SXE: add(szItem, charsmax(szItem), "\r [sXe]")
		}

		menu_additem(iMenu, szItem)
	}

	menu_display(id, iMenu)
	return PLUGIN_HANDLED
}

public ListPlayers_Handler(id, iMenu, iItem)
{
	menu_destroy(iMenu)
	return PLUGIN_HANDLED
}

[vini2001]

88/5000
it's perfect I just sent something wrong

It would be like this

SXE - VALVE_4: 0
without SXE - VALVE_4: 4

[OciXCrom]

Check now.

[vini2001]

Thanks my friend