Заявка за код, админ скин и вип модели

[viewsonic]

админ скин модели с флаг "m"
вип скин модели с флаг "p"
ще помоля само да ми се посочи къде трябва да сложа моделите във самият сма код благодаря ..

[DaRk_StyLe]

В кода на плъгина пишеш само имената на самите модели, погрижил съм се за останалото. Описал съм всичко, като коментар в кода, но ако има нещо неясно, питай.

► Покажи скъсения текст

Код за потвърждение: Избери целия код

/*
	tmodel_kick	- името на модела на терористите с флаг ADMIN_KICK 
	ctmodel_kick	- името на модела на контра-терористите с флаг ADMIN_KICK
	
	tmodel_ban	- името на модела на терористите с флаг ADMIN_BAN 
	ctmodel_ban	- името на модела на контра-терористите с флаг ADMIN_BAN
	
	(!) моделите се добавят в директорията, спазвайки следния формат -> models/player/име-на-модела/име-на-модела.mdl (!)
	(!) ако решиш да добавяш още модели, спазваш формата -> "име на модела на терористите", "име на модела на контра-терористите", флаг за достъп (!)
	(!) след последния модел не се добавя запетая (!)
*/


#include < amxmodx >
#include < fakemeta >

enum _:ModelsInfo
{
	Terrorists_Model[ 32 ],
	CT_Model[ 32 ],
	Flag
};

new const Models[][ ModelsInfo ] =
{
	{ "tmodel_kick", "ctmodel_kick", ADMIN_KICK },
	{ "tmodel_ban", "ctmodel_ban", ADMIN_BAN }
};

public plugin_precache()
{
	new T_File[ 128 ], CT_File[ 128 ];
	
	for( new i = 0; i < sizeof( Models ); i++ )
	{
		formatex( T_File, charsmax( T_File ), "models/player/%s/%s.mdl", Models[ i ][ Terrorists_Model ], Models[ i ][ Terrorists_Model ] );
		formatex( CT_File, charsmax( CT_File ), "models/player/%s/%s.mdl", Models[ i ][ CT_Model ], Models[ i ][ CT_Model ] );
		
		precache_model( T_File );
		precache_model( CT_File );
	}
}

public plugin_init()
{
	register_plugin( "Admin Models", "1.0", "DaRk_StyLe" );
	register_forward( FM_SetClientKeyValue, "Forward_KeyValue" );
}

public Forward_KeyValue( id, const buffer[], const key[] )
{
	if( equal( key, "model" ) )
	{
		new CurrentModel[ 32 ];
		get_user_info( id, "model", CurrentModel, charsmax( CurrentModel ) );
		
		new Team = get_pdata_int( id, 114 );
		
		for( new i = 0; i < sizeof( Models ); i++ )
		{
			if( get_user_flags( id ) & Models[ i ][ Flag ] )
			{
				if( !equal( CurrentModel, Models[ i ][ Terrorists_Model ] ) || !equal( CurrentModel, Models[ i ][ CT_Model ] ) )
				{
					switch( Team )
					{
						case 1: set_user_info( id, "model", Models[ i ][ Terrorists_Model ] );
						case 2: set_user_info( id, "model", Models[ i ][ CT_Model ] );
					}
				}
			}
		}
		
		return FMRES_SUPERCEDE;
	}
	
	return FMRES_IGNORED;
}

[viewsonic]

добре, благодаря много

[DaRk_StyLe]

Когато настройваш моделите, имай предвид, че кода съм го копирал от друга тема, затова флаговете не отговарят на исканите от теб, необходимо е да си ги зададеш.

[viewsonic]

нямам много опит във скриптирването но ще помоля да го едитнат

[DaRk_StyLe]

Моделите и необходимият флаг за достъп до тях се задават от тези редове:

Код за потвърждение: Избери целия код

new const Models[][ ModelsInfo ] =
{
	{ "tmodel_kick", "ctmodel_kick", ADMIN_KICK },
	{ "tmodel_ban", "ctmodel_ban", ADMIN_BAN }
};

Ето какво се получава в конкретния случай:

tmodel_kick и ctmodel_kick са имената на моделите за терористите и контра-терористите, които имат флаг ADMIN_KICK;
tmodel_ban и ctmodel_ban са имената на моделите за терористите и контра-терористите, които имат флаг ADMIN_BAN;

От теб се изисква само да си промениш тези неща.

[viewsonic]

Код за потвърждение: Избери целия код

new const Models[][ ModelsInfo ] =
{
	{ "vip_te", "vip_ct", ADMIN_KICK },
	{ "admin_te", "admin_ct", ADMIN_BAN }

сложих моделите за админ и вип но сървъра след глобален рестарт или рестарт от конзола "amx_map...." замръзва без ерори във логове !

[DaRk_StyLe]

Тествах плъгина преди да го споделя в другата тема, нямаше подобни проблеми. Нека се уверим, че всичко е направено правилно.

В твоя случай кодът на плъгина трябва да изглежда ето така:

Код за потвърждение: Избери целия код

new const Models[][ ModelsInfo ] =
{
	{ "vip_te", "vip_ct", ADMIN_KICK },
	{ "admin_te", "admin_ct", ADMIN_BAN }
};

Това означава, че моделите с имена "vip_te" & "vip_ct" са достъпни за играчите с флаг ADMIN_KICK, а моделите с имена "admin_te" & "admin_ct" са достъпни за играчите с флаг ADMIN_BAN.

Отделно, необходимо е тези модели да бъдат поставени в директорията models/player, като се спазва следният формат:

• models/player/vip_te/vip_te.mdl
• models/player/vip_ct/vip_ct.mdl
• models/player/admin_te/admin_te.mdl
• models/player/admin_ct/admin_ct.mdl

Ако всичко това е изпълнено, предостави самите модели, за да направя и аз тест на плъгина с тях.

---

► Покажи скъсения текст

[viewsonic]

заповядай http://www.mediafire.com/file/e33g0p7zr ... r.rar/file

[DaRk_StyLe]

Още при разархивирането се натъквам на разминавания.

• папка "vip_t", модел vip_te.mdl
• папка "admin_t", модел admin_te.mdl

---

Понеже ми изпрати лично съобщение дали ще мога да оправя проблема, ето снимков материал за правилната работа на плъгина:

► Покажи скъсения текст

Решението на проблема ти вече съм го предоставил - виж в предишните мнения как трябва да бъдат поставени моделите в директорията models/player/. Темата с това се изчерпва, следователно я заключвам. Предоставил съм работещ плъгин, инсталацията е ваша грижа.