Round start sound

[Jeff]

Здравейте,
Търся плъгин, който прави следното:
В началото на всеки рунд да се пуска музика (.wav файл), която да чуват всички играчи в сървъра.
Когато рундът свърши, музиката трябва да спре (независимо до къде е стигнала) и следващия рунд да започва отново.
Също така, ако е възможно, бих искал плъгинът на случаен принцип да пуска музика (да кажем има 5 различни .wav файла с музика).
Благодаря.

[KnowN]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

Код за потвърждение: Избери целия код

#include <amxmodx>

new const lstSound[][] = { "misc/load1.mp3" };

public plugin_init() 
{
	register_plugin( "Round Start Sound", "1.0", "AMXX Community" );
	register_event( "HLTV", "event_new_round", "a", "1=0", "2=0" );
}

public plugin_precache() 
{
	new CurSnd[128];
	
	copy( CurSnd, 127, lstSound[0] );
	format( CurSnd, 127, "sound/%s", CurSnd );    
	                
	if ( equali( CurSnd[strlen(CurSnd)-4], ".mp3" ) )   
	{
		if ( file_exists( CurSnd ) )
			precache_generic( CurSnd );
	}
	else      
	{
		if ( file_exists( CurSnd ) )
			precache_sound( CurSnd[6] ); 
	}
}

public event_new_round()
{
	new CurSnd[128];
	
	copy( CurSnd, 127, lstSound[0] );
	format( CurSnd, 127, "sound/%s", CurSnd ); 
	
	if( equali( CurSnd[strlen( CurSnd ) - 4 ], ".mp3" ) )
		client_cmd( 0, "mp3 play %s", CurSnd )
	else
		client_cmd( 0, "spk %s", CurSnd[6] )
		
}

[DaRk_StyLe]

Звуците добавяш, като спазваш следния синтаксис:

Код за потвърждение: Избери целия код

new const Sounds[][] =
{
	"ambience/cow.wav",
	"ambience/crow.wav",
	"ambience/sheep.wav",
	"ambience/Opera.wav",
	"ambience/sparrow.wav" // <-- след последния звук не се слага запетая!
};

Тъй като работиш с .wav, не добавяй sound/ директорията в пътя до файла, директно следващата директория.

Плъгинът го направих в края на рунда да спира всички звуци освен тези за победа на отборите, защото се получа пълна тишина в противен случай, което не е много приятно. Ако все пак искаш да е пълна тишина, ще ти предоставя и подобна версия.

• Версия със звуците за победа:

► Покажи скъсения текст

Код за потвърждение: Избери целия код

#include < amxmodx >

new const Sounds[][] =
{
	"ambience/cow.wav",
	"ambience/crow.wav",
	"ambience/sheep.wav",
	"ambience/Opera.wav",
	"ambience/sparrow.wav"
};

new bool: TerroristsWin;
new bool: CTWin;

public plugin_precache()
{
	for( new i = 0; i < sizeof( Sounds ); i++ )
	{
		precache_sound( Sounds[ i ] );
	}
}

public plugin_init()
{
	register_plugin( "Round Sounds", "1.0", "DaRk_StyLe" );
	
	register_event( "HLTV", "Event_HLTV", "a", "1=0", "2=0" );
	register_logevent( "Event_Round_End", 2, "1=Round_End" );
	
	register_event( "SendAudio", "Event_TerroristsWin", "a", "2=%!MRAD_terwin" );
	register_event( "SendAudio", "Event_CTWin", "a", "2&%!MRAD_ctwin" );
}

public Event_HLTV()
{
	client_cmd( 0, "spk ^"%s^"", Sounds[ random( sizeof( Sounds ) ) ] );
}

public Event_Round_End()
{
	client_cmd( 0, "stopsound" );
	
	if( TerroristsWin )
	{
		client_cmd( 0, "speak ^"%!MRAD_TERWIN^"" );
	}
	else if( CTWin )
	{
		client_cmd( 0, "speak ^"%!MRAD_CTWIN^"" );
	}
}

public Event_TerroristsWin()
{
	TerroristsWin = true;
	CTWin = false;
}

public Event_CTWin()
{
	CTWin = true;
	TerroristsWin = false;
}

---

• Версия "мълчанието на агнетата":

► Покажи скъсения текст

Код за потвърждение: Избери целия код

#include < amxmodx >

new const Sounds[][] =
{
	"ambience/cow.wav",
	"ambience/crow.wav",
	"ambience/sheep.wav",
	"ambience/Opera.wav",
	"ambience/sparrow.wav"
};

public plugin_precache()
{
	for( new i = 0; i < sizeof( Sounds ); i++ )
	{
		precache_sound( Sounds[ i ] );
	}
}

public plugin_init()
{
	register_plugin( "Round Sounds", "1.0", "DaRk_StyLe" );
	
	register_event( "HLTV", "Event_HLTV", "a", "1=0", "2=0" );
	register_logevent( "Event_Round_End", 2, "1=Round_End" );
}

public Event_HLTV()
{
	client_cmd( 0, "spk ^"%s^"", Sounds[ random( sizeof( Sounds ) ) ] );
}

public Event_Round_End()
{
	client_cmd( 0, "stopsound" );
}

[JackEyedJones]

Код за потвърждение: Избери целия код

register_logevent("PriNachaloNaRunda", 2, "1=Round_Start");

За предпочитане в такива плъгини е звука да се пуска след Freeze Time, а не както е в случая веднага след като играча бъде Respawn-нат.

[DaRk_StyLe]

Ще редактирам кода, ако авторът на темата желае това. Благодаря, че ми показа как се хваща въпросното събитие, и аз да науча нещо полезно.

[Jeff]

Благодаря за плъгина, но имам малък проблем.
Използвам друг плъгин за звуци в края на рунда.
Но в момента чувам стандартните звуци (T win / CT win).
Бих искал пак да си чувам моите звуци.
Те са в misc папката, ако това има особено значение.

[JackEyedJones]

viewtopic.php?f=21&t=69

[DaRk_StyLe]

Благодаря за плъгина, но имам малък проблем.
Използвам друг плъгин за звуци в края на рунда.
Но в момента чувам стандартните звуци (T win / CT win).
Бих искал пак да си чувам моите звуци.
Те са в misc папката, ако това има особено значение.

Код за потвърждение: Избери целия код

#include < amxmodx >

new const Sounds[][] =
{
	"ambience/cow.wav",
	"ambience/crow.wav",
	"ambience/sheep.wav",
	"ambience/Opera.wav",
	"ambience/sparrow.wav"
};

public plugin_precache()
{
	for( new i = 0; i < sizeof( Sounds ); i++ )
	{
		precache_sound( Sounds[ i ] );
	}
}

public plugin_init()
{
	register_plugin( "Round Sounds", "1.0", "DaRk_StyLe" );
	register_event( "HLTV", "Event_HLTV", "a", "1=0", "2=0" );
}

public Event_HLTV()
{
	client_cmd( 0, "spk ^"%s^"", Sounds[ random( sizeof( Sounds ) ) ] );
}

[Jeff]

Благодаря, сега вече работи перфектно !