Първи рунд(загряващ) с ножове и респаун и граната

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
Ant1Lamer
Извън линия
Потребител
Потребител
Мнения: 217
Регистриран на: 08 Окт 2016, 00:03
Се отблагодари: 18 пъти
Получена благодарност: 3 пъти

Първи рунд(загряващ) с ножове и респаун и граната

Мнение от Ant1Lamer » 15 Ное 2018, 12:02

Заглавието аз имам някакъв, но по спомен правеше някакъв проблем някой ги пускаше с пистолети някой не не почваше да речем от втория рунд ми от третия или четвъртия прикачвам го да го погледнете
Прикачени файлове
Autorestart_Knife.sma
(12.87 KiB) Свалено 123 пъти
Autorestart_Knife.sma
(12.87 KiB) Свалено 123 пъти
НАУЧИ ПРАВИЛАТА, ЗА ДА ЗНАЕШ КАК ПОРЯДЪЧНО ДА ГИ НАРУШАВАШ!!!

Аватар
thespritofthebeast
Извън линия
Потребител
Потребител
Мнения: 20
Регистриран на: 11 Ное 2018, 22:09

Първи рунд(загряващ) с ножове и респаун и граната

Мнение от thespritofthebeast » 15 Ное 2018, 20:28

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Simple Knife Warump"
#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

#define TASKID 1234

new hudtimer, cvar, hudhandler, mp_freezetime, value

public plugin_init() 
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
		
	register_message(get_user_msgid("TextMsg") ,"message_TextMsg")	
	
	register_event("CurWeapon","switchweapon","be","1=1","2!29") 
	
	register_dictionary("simple_warmup.txt")
	
	cvar = register_cvar("warmup_timer", "60")
	
	hudhandler = CreateHudSyncObj()
}

public plugin_cfg() 
{
	mp_freezetime = get_cvar_pointer("mp_freezetime")
	
	set_task(10.0, "read_vars")
}

public read_vars()
{	
	value = get_pcvar_num(mp_freezetime)
}

public message_TextMsg(const MsgId, const MsgDest, const MsgEntity)
{	
	static message[64]
	get_msg_arg_string(2, message, charsmax(message))
	
	if(equal(message, "#Game_Commencing"))
	{
		hudtimer = get_pcvar_num(cvar)
		
		if(hudtimer == -1)
			return
		
		formatex(message, charsmax(message), "%L", LANG_PLAYER, "WARUMP_START")	
		set_msg_arg_string(2, message)
		
		set_task(1.0, "restart", TASKID, _, _, "b")		
		set_pcvar_num(mp_freezetime, 0)		
	}
	if(equal(message, "#Game_will_restart_in"))
	{
		formatex(message, charsmax(message), "%L", LANG_PLAYER, "WARUMP_END")	
		set_msg_arg_string(2, message)
	}
}

public restart()
{			
	if(hudtimer <= 0)
	{
		remove_task(TASKID)
		set_cvar_num("sv_restartround", 1)
		set_pcvar_num(mp_freezetime, value)		
	} 
	else 
	{
		set_hudmessage(255,255,255,-1.0,0.9,0,6.0,1.0,0.1,0.2)	
		ShowSyncHudMsg(0, hudhandler, "%L", LANG_PLAYER, "COUNTING", hudtimer)
	}	
	hudtimer--
}

public switchweapon(id)
{
	if(task_exists(TASKID)) 
	{
		engclient_cmd(id, "weapon_knife")
	}
}

Аватар
Ant1Lamer
Извън линия
Потребител
Потребител
Мнения: 217
Регистриран на: 08 Окт 2016, 00:03
Се отблагодари: 18 пъти
Получена благодарност: 3 пъти

Първи рунд(загряващ) с ножове и респаун и граната

Мнение от Ant1Lamer » 15 Ное 2018, 22:11

неее не ме устройва ползвал съм го и в него имаше някакви проблеми не помна точно какво
НАУЧИ ПРАВИЛАТА, ЗА ДА ЗНАЕШ КАК ПОРЯДЪЧНО ДА ГИ НАРУШАВАШ!!!

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Първи рунд(загряващ) с ножове и респаун и граната

Мнение от OciXCrom » 17 Ное 2018, 21:20

Виж този - изработил съм го в някоя предишна заявка:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <csx>
#include <fun>
#include <hamsandwich>

#if AMXX_VERSION_NUM < 183
	#include <dhudmessage>
#endif

#if !defined DMG_GRENADE
	#define DMG_GRENADE (1<<24)
#endif

#define GREN_DELAY 0.5
#define HUD_FREQ 1.0
#define TASK_MESSAGE 332912
#define WARMUP_DURATION 120

new bool:g_bLive, g_iTimer

public plugin_init()
{
	register_plugin("Warmpun Round", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
	RegisterHam(Ham_TraceAttack, "player", "PrePlayerAttack")
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start")
	g_iTimer = WARMUP_DURATION
	set_task(HUD_FREQ, "display_message", TASK_MESSAGE, .flags = "b")
}

public CS_OnBuyAttempt(id, iItem)
{
	if(g_iTimer)
	{
		client_print(id, print_center, "No buying during warmup!")
		return PLUGIN_HANDLED
	}
	
	return PLUGIN_CONTINUE
}

public OnRoundStart()
{
	if(g_bLive)
	{
		set_dhudmessage(random(256), random(256), random(256), -1.0, 0.2, 0, 0.1, 1.0, 0.1, 0.1)
		show_dhudmessage(0, "WARMUP ENDED!^nWe're now live!")
		g_bLive = false
	}
}
	
public OnPlayerSpawn(id)
{
	if(!is_user_alive(id) || !g_iTimer)
		return
		
	give_grenade(id)
}

public PrePlayerAttack(iVictim, iAttacker, Float:fDamage, Float:fDirection[3], iTraceHandle, iDamageBits)
	return (g_iTimer > 0 && iDamageBits != DMG_GRENADE) ? HAM_SUPERCEDE : HAM_IGNORED

public grenade_throw(id, iGrenadeId, iGrenadeType)
{
	if(!g_iTimer)
		return
		
	set_task(GREN_DELAY, "give_grenade", id)
}

public give_grenade(id)
{
	if(is_user_connected(id) && g_iTimer > 0)
	{
		give_item(id, "weapon_hegrenade")
		engclient_cmd(id, "weapon_hegrenade")
	}
}

public display_message()
{
	new iPlayers[32], iPnum
	get_players(iPlayers, iPnum, "b")
	
	for(new i, iPlayer; i < iPnum; i++)
	{
		iPlayer = iPlayers[i]
		
		if(1 <= get_user_team(iPlayer) <= 2)
			ExecuteHamB(Ham_CS_RoundRespawn, iPlayer)
	}
	
	set_dhudmessage(random(256), random(256), random(256), -1.0, 0.2, 0, 0.1, 1.0, 0.1, 0.1)
	show_dhudmessage(0, "[WARMUP: %i]^nOnly HE Grenades do damage!", g_iTimer)
	
	if(--g_iTimer == 0)
	{
		remove_task(TASK_MESSAGE)
		server_cmd("sv_restartround 1")
		g_bLive = true
	}
}

Аватар
Ant1Lamer
Извън линия
Потребител
Потребител
Мнения: 217
Регистриран на: 08 Окт 2016, 00:03
Се отблагодари: 18 пъти
Получена благодарност: 3 пъти

Първи рунд(загряващ) с ножове и респаун и граната

Мнение от Ant1Lamer » 17 Ное 2018, 21:49

А точно това търсех знаех че беше правил, но не можех да намеря темата мерси!
НАУЧИ ПРАВИЛАТА, ЗА ДА ЗНАЕШ КАК ПОРЯДЪЧНО ДА ГИ НАРУШАВАШ!!!

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: Bing [Bot] и 15 госта