Редактиране на плъгини само за CT

[Eternal]

Здравейте!
Може ли да редактирате тези два плъгини така, че vampire плъгина да е само за CT и multijump плъгина да е само за CT които са и админи?

[OciXCrom]

Какъв е флагът за админите?

[Eternal]

Ако може бих искал да е ADMIN_KICK - Flag "c"

[OciXCrom]

Прочети правилата на форума. Качването на .amxx файлове е забранено! Линковете са премахнати.

Плъгините са отвратително направени и нямам намерения да си играя да правя промени по тях. Ето ти в пъти по-добри такива + редактирани както искаш:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>

#define HUD_ENABLED
#define HUD_COLOR 0, 255, 0
#define HUD_POSITION -1.0, 0.15
#define HUD_DURATION 1.5

#define SCREENFADE_ENABLED
#define SCREENFADE_COLOR_R 0
#define SCREENFADE_COLOR_G 0
#define SCREENFADE_COLOR_B 200
#define SCREENFADE_COLOR_A 75

enum _:Cvars
{
	amx_vampire_hp,
	amx_vampire_hp_hs,
	amx_vampire_max_hp
}

new g_eCvars[Cvars]

#if defined HUD_ENABLED
new g_iObject
#endif

#if defined SCREENFADE_ENABLED
new g_iScreenFade
#endif

public plugin_init()
{
	register_plugin("Vampire", "1.0", "OciXCrom")
	register_event("DeathMsg", "OnPlayerKilled", "a")
	g_eCvars[amx_vampire_hp] = register_cvar("amx_vampire_hp", "15")
	g_eCvars[amx_vampire_hp_hs] = register_cvar("amx_vampire_hp_hs", "40")
	g_eCvars[amx_vampire_max_hp] = register_cvar("amx_vampire_max_hp", "100")

	#if defined HUD_ENABLED
	g_iObject = CreateHudSyncObj()
	#endif

	#if defined SCREENFADE_ENABLED
	g_iScreenFade = get_user_msgid("ScreenFade")
	#endif
}

public OnPlayerKilled()
{
	new iAttacker = read_data(1), iVictim = read_data(2)
	
	if(!is_user_connected(iAttacker) || iAttacker == iVictim || cs_get_user_team(iAttacker) != CS_TEAM_CT)
		return

	new iHealth = get_user_health(iAttacker), iMax = get_pcvar_num(g_eCvars[amx_vampire_max_hp])

	if(iHealth >= iMax)
		return

	new iAdd = read_data(3) ? get_pcvar_num(g_eCvars[amx_vampire_hp_hs]) : get_pcvar_num(g_eCvars[amx_vampire_hp])
	set_user_health(iAttacker, clamp(iHealth + iAdd, .max = iMax))

	#if defined HUD_ENABLED
	set_hudmessage(HUD_COLOR, HUD_POSITION, .holdtime = HUD_DURATION)
	ShowSyncHudMsg(iAttacker, g_iObject, "Healed +%i HP", iAdd)
	#endif

	#if defined SCREENFADE_ENABLED
	message_begin(MSG_ONE, g_iScreenFade, {0, 0, 0}, iAttacker)
	write_short(1<<10)
	write_short(1<<10)
	write_short(0x0000)
	write_byte(SCREENFADE_COLOR_R)
	write_byte(SCREENFADE_COLOR_G)
	write_byte(SCREENFADE_COLOR_B)
	write_byte(SCREENFADE_COLOR_A)
	message_end()
	#endif
}

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <engine>

#define MAX_JUMPS 2
#define ADMIN_FLAG ADMIN_KICK

new bool:g_bDoJump[33], g_iJumps[33]

public plugin_init()
{
	register_plugin("Multijump", "1.0", "OciXCrom")
}

public client_putinserver(id)
{
	g_iJumps[id] = 0
	g_bDoJump[id] = false
}

public client_PreThink(id)
{
	if(!is_user_alive(id) || cs_get_user_team(id) != CS_TEAM_CT || !(get_user_flags(id) & ADMIN_FLAG))
		return PLUGIN_CONTINUE
	
	new iNewButton = get_user_button(id)
	new iOldButton = get_user_oldbutton(id)
	
	if((iNewButton & IN_JUMP) && !(get_entity_flags(id) & FL_ONGROUND) && !(iOldButton & IN_JUMP))
	{
		if(g_iJumps[id] < MAX_JUMPS)
		{
			g_bDoJump[id] = true
			g_iJumps[id]++
			return PLUGIN_CONTINUE
		}
	}
	
	if((iNewButton & IN_JUMP) && (get_entity_flags(id) & FL_ONGROUND))
	{
		g_iJumps[id] = 0
		return PLUGIN_CONTINUE
	}
	
	return PLUGIN_CONTINUE
}

public client_PostThink(id)
{
	if(!is_user_alive(id))
		return PLUGIN_CONTINUE
		
	if(g_bDoJump[id])
	{
		new Float:flVelocity[3]	
		entity_get_vector(id, EV_VEC_velocity, flVelocity)
		flVelocity[2] = random_float(265.0, 285.0)
		entity_set_vector(id, EV_VEC_velocity, flVelocity)
		g_bDoJump[id] = false
	}
	
	return PLUGIN_CONTINUE
}

[Eternal]

Извинявам се, че пиша толкова късно. И двата плъгина работят супер. Благодаря!