Супер awp 1 vs 3

[AK-47]

Здравейте.
Искам да ми изработите плъгин за супер awp.

Обяснение: Когато остане 1 цт срещу повече от 3 терориста да му дава awp (на цт) с 3 патрона, което бие 10к dmg, а на вип-а да са 6 патрона, ви флаг "b"

Когато му даде awp-то да не му се махат другите оръжия, след като свършат патроните на awp-то, то директно да се махне.

[OciXCrom]

Ползваш ли ReAPI?

[AK-47]

Ползваш ли ReAPI?

He.

[AK-47]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

Извинявам се, че правя втори пост, но ако може да погледнете заявката.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fakemeta_util>
#include <fun>
#include <hamsandwich>

#if defined client_disconnected
	#define client_disconnect client_disconnected
#endif

#define CT_FACTOR 1
#define T_FACTOR 3

#define VIP_FLAG ADMIN_RESERVATION

#define AWP_BULLETS 3
#define AWP_BULLETS_VIP 6
#define AWP_DAMAGE 10000.0

new bool:g_bSuper[33]

public plugin_init()
{
	register_plugin("Super AWP", "1.0", "OciXCrom")
	register_event("DeathMsg", "check_players", "a")
	register_logevent("OnRoundEnd", 2, "1=Round_End")
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
	RegisterHam(Ham_Weapon_PrimaryAttack, "weapon_awp", "OnPrimaryAttack", 1);
}

public client_putinserver(id)
	g_bSuper[id] = false

public client_disconnect()
	check_players()

public PreTakeDamage(iVictim, iInflictor, iAttacker)
{
	if(g_bSuper[iAttacker])
		SetHamParamFloat(4, AWP_DAMAGE)
}

public OnRoundEnd()
	arrayset(g_bSuper, false, sizeof(g_bSuper))

public OnPrimaryAttack(iEnt)
{
	if(!pev_valid(iEnt))
		return

	if(!cs_get_weapon_ammo(iEnt))
		fm_strip_user_gun(get_pdata_cbase(iEnt, 41, 4), CSW_AWP)
}

public check_players()
{
	new iPlayers[32], iPnum
	get_players(iPlayers, iPnum, "ae", "CT")

	if(iPnum == CT_FACTOR)
	{
		new id = iPlayers[0]
		get_players(iPlayers, iPnum, "ae", "T")

		if(iPnum > T_FACTOR)
		{
			g_bSuper[id] = true
			cs_set_weapon_ammo(give_item(id, "weapon_awp"), (get_user_flags(id) & VIP_FLAG) ? AWP_BULLETS_VIP : AWP_BULLETS)
			cs_set_user_bpammo(id, CSW_AWP, 0)
		}
	}
}