Заявка за golden awp

[Fatall]

Здравейте, имам респаун сървър и искам всеки който има 16000$ да може да си купи AWP който да прави double дмг и играчът да свети в жълто

[OciXCrom]

Команда: /gawp
Настрой си моделите в #define редовете.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <fakemeta>
#include <fun>
#include <hamsandwich>

#define GOLDEN_AWP_V_MODEL "models/v_awp.mdl"
#define GOLDEN_AWP_P_MODEL "models/p_awp.mdl"
#define GOLDEN_AWP_DMG_MULTIPLIER 2
#define GOLDEN_AWP_PRICE 16000
#define GOLDEN_AWP_GLOW_COLOR 255, 255, 0
#define GOLDEN_AWP_GLOW_ALPHA 40

new bool:g_bHasGolden[33]

public plugin_init()
{
	register_plugin("Golden AWP", "1.0", "OciXCrom")
	register_clcmd("say /gawp", "Cmd_BuyGolden")
	register_clcmd("say_team /gawp", "Cmd_BuyGolden")
	register_event("CurWeapon", "OnSelectAWP", "be", "1=1", "2=18")
	register_event("DeathMsg", "OnPlayerKilled", "a")
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage")
	CC_SetPrefix("&x04[Golden AWP]")
}

public plugin_precache()
{
	#if defined GOLDEN_AWP_V_MODEL
	precache_model(GOLDEN_AWP_V_MODEL)
	#endif
	
	#if defined GOLDEN_AWP_P_MODEL
	precache_model(GOLDEN_AWP_P_MODEL)
	#endif
}

public client_putinserver(id)
	g_bHasGolden[id] = false

public Cmd_BuyGolden(id)
{
	if(g_bHasGolden[id])
		CC_SendMessage(id, "You already have a &x04Golden AWP&x01.")
	else
	{
		new iMoney = cs_get_user_money(id)
		
		if(iMoney >= GOLDEN_AWP_PRICE)
		{
			g_bHasGolden[id] = true
			cs_set_user_money(id, iMoney - GOLDEN_AWP_PRICE)
			CC_SendMessage(id, "You bought a &x03Golden AWP &x01for &x04%i$", GOLDEN_AWP_PRICE)
			set_user_rendering(id, kRenderFxGlowShell, GOLDEN_AWP_GLOW_COLOR, kRenderTransAlpha, GOLDEN_AWP_GLOW_ALPHA)
			give_item(id, "weapon_awp")
			cs_set_user_bpammo(id, CSW_AWP, 30)
			
			if(get_user_weapon(id) == CSW_AWP)
				OnSelectAWP(id)
		}
		else CC_SendMessage(id, "You need &x04%i$ &x01to purchase this.", GOLDEN_AWP_PRICE)
	}
	
	return PLUGIN_HANDLED
}

public OnPlayerKilled()
{
	new iVictim = read_data(2)
	
	if(!is_user_connected(iVictim))
		return

	if(g_bHasGolden[iVictim])
	{
		g_bHasGolden[iVictim] = false
		set_user_rendering(iVictim)
	}
}

public OnSelectAWP(id)
{
	#if defined GOLDEN_AWP_V_MODEL
	set_pev(id, pev_viewmodel2, GOLDEN_AWP_V_MODEL)
	#endif
	
	#if defined GOLDEN_AWP_P_MODEL
	set_pev(id, pev_weaponmodel2, GOLDEN_AWP_P_MODEL)
	#endif
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage)
{
    if(is_user_alive(iAttacker) && iAttacker != iVictim && g_bHasGolden[iAttacker])
        SetHamParamFloat(4, fDamage * GOLDEN_AWP_DMG_MULTIPLIER)
}

[Fatall]

Дава ми грешка

Код за потвърждение: Избери целия код

Error: server failed to transmit file 'models/Fatall_Error/v_awp.mdl'
Error: server failed to transmit file 'models/Fatall_Error/p_awp.mdl'
Error: could not load file models/Fatall_Error/v_awp.mdl
Model models/Fatall_Error/v_awp.mdl not found and not available from server
Cannot continue without model models/Fatall_Error/v_awp.mdl, disconnec

server.cfg
sv_allowdownload 1
sv_downloadurl "http://svdl.iplay.bg"

[OciXCrom]

Не виждам моделите да са качени на downloadurl.
http://svdl.iplay.bg/models/Fatall_Error

[Fatall]

Като сложа този скин и бъгва забива цс-а

4659-zlote_awp.rar

(416.25 KiB) Свалено 122 пъти

4659-zlote_awp.rar

(416.25 KiB) Свалено 122 пъти

Код за потвърждение: Избери целия код

#define GOLDEN_AWP_V_MODEL "models/Fatall_Error/v_awp.mdl"
#define GOLDEN_AWP_P_MODEL "models/Fatall_Error/p_awp.mdl"

[OciXCrom]

Как може играта да забива от скин?! Казах ти, че моделите НЕ СА КАЧЕНИ на downloadurl, съответно няма как да ти работи сървърът.

[illusion]

Кажи на хоста ти да ти добавят файловете на downloadurl-a..

[Fatall]

Кроме като взема awp взема парите но не дава awp

[OciXCrom]

Кроме като взема awp взема парите но не дава awp

Оправено.

[Fatall]

Сега обаче няма по 2x dmg