Търся плъгин за "резервация на ник".

[iv69]

Това запазване по какъв начин ще става? Трябва да е или по ИП или по SteamID, в противен случай трябва да се ползва парола. При положение, че повечето играчи в България са с динамично ИП и/или нямат SteamID, не виждам как ще стане?

Как така нямат SteamID? Всяка версия, независимо Non-Steam или Steam имат SteamID, поне status командата в конзолата го доказва? Пък и + това, аз как се правя в сървъра ми админ по steam id, а съм non-steam играч. Не желая да споря с теб, понеже разбираш милиарди пъти повече от мен, но тук мисля, че не си прав. Пък и нека погледнем повечето чужди сървъри, над 80% от тях ползват запазване по SteamID, било то на Ammo Packs, XP за ранк система, или да направят някого админ...

Част от кракнатите игри имат SteamID, но не е оригинално. Друга част от кракнатите игри имат VALVE_ID_LAN, което е главният проблем, тъй като е едно и също за всеки играч.

Моля те , ще ни е достатъчно и ще сме безкрайно благодарни ако плъгина запазва ника само на онези които имат: 1.или оригинален SteamID, или
2.SteamID, но не е оригинално.. А за другата част от кракнатите игри, които имат VALVE_ID_LAN, не мисля , че трябва да се тревожим ... За тях дори в някои форуми пишат плъгини които да не ги допускат в сървъра... Цитираните две групи са над 90% от играещите cs1.6... За мен това е напълно достатъчно... А ония които са с кракнати игри и имат VALVE_ID_LAN ... или само VALVE и номер.. ако искат резервация на ник сами ще си решат проблема, просто като си "пачнат" ЦС-а с по-нова версия пач... !!!
Благодаря за разбирането.

[OciXCrom]

Добър начин да накараш играчите да ползват игра с SteamID е като някои неща в сървъра ги направиш недостъпни за тези с VALVE_ID_LAN. Аз в мой сървър съм направил един куп екстри достъпни само за Steam играчи и вече почти не се забелязва нито един играч с VALVE_ID_LAN. Ще направя плъгина по-късно, че в момента съм зает с друго нещо.

[iv69]

По-скоро са проблем дребните терикати със стийм-ИД чейнджъри но си има плъгин и за това !!!

Би ли го споделил този плъгин със нас

без проблем не съм дечко и не си пазя играчките само за себе си :

Ползвам плъгина с име : "Steam Changer Busters v 1.1" , а записа му в plugins.ini e: SC_Busters.amxx ...
Досега за близо над година и половина ползване само с трима не съм се справил...но и за тях има начин : ползваш специален плъгин за банване а не обикновените версии на amxx.bans... Тоест който търси намира... както хакове така и решения за тях...

Добавено преди 8 минути 31 секунди:

Добър начин да накараш играчите да ползват игра с SteamID е като някои неща в сървъра ги направиш недостъпни за тези с VALVE_ID_LAN. Аз в мой сървър съм направил един куп екстри достъпни само за Steam играчи и вече почти не се забелязва нито един играч с VALVE_ID_LAN. Ще направя плъгина по-късно, че в момента съм зает с друго нещо.

Кой е твоя сървър. както го написа звучи , сякаш е само един !!! безкрайно съм любопитен , и ако не е тайна дай ми ИП-то му , ще е първия в моите фаворити,... Благодаря !

[You Owe Me]

Ако може сподели кода.

[iv69]

Ако може сподели кода.

За ??? Ако става думаа за стийм-ИД чейнджър-хакерите вече писах ! Погледни по-горе... Хайде да не флудим в темата ? Има сайтове където има и плъгина и кода ... Поразрови се малко де ....

[You Owe Me]

Хайде-хайде, ама плъгина е изтрит и го няма в нета... Затова, може ли? )

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <nvault>

#define MSG_DELAY 15.0
#define MSG_TASK 300533
#define PLUGIN_VERSION "1.0"

new g_iVault

public plugin_init()
{
	register_plugin("Nick Protection", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXNickProtection", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_clcmd("say /nick", "Cmd_Nick")
	register_clcmd("say_team /nick", "Cmd_Nick")
	g_iVault = nvault_open("NickProtection")
	CC_SetPrefix("&x04[Nick Protection]")
}

public plugin_end()
	nvault_close(g_iVault)

public client_authorized(id)
{
	new szAuth[35]
	get_user_authid(id, szAuth, charsmax(szAuth))
		
	if(!is_valid_steam(szAuth))
		return
		
	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
	{
		if(!equal(szAuth, szData))
			server_cmd("kick #%i ^"Tozi nick e zashtiten sus SteamID!^"", get_user_userid(id))
	}
	else set_task(MSG_DELAY, "Inform_User", id + MSG_TASK)
}

public Inform_User(id)
{
	id -= MSG_TASK
	
	if(is_user_connected(id))
		CC_SendMessage(id, "Napishi &x03/nick &x01za da si zashtitish nicka po SteamID!")
}

public Cmd_Nick(id)
{
	new szAuth[35]
	get_user_authid(id, szAuth, charsmax(szAuth))
	
	if(!is_valid_steam(szAuth))
	{
		CC_SendMessage(id, "Trqbva da imash SteamID za da mojesh da polzvash sistemata!")
		return PLUGIN_HANDLED
	}
	
	new szData[35], szName[32]
	get_user_name_lower(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
		CC_SendMessage(id, "Tozi nick veche e zashtiten sus SteamID &x04%s", szData)
	else if(nvault_get(g_iVault, szAuth, szData, charsmax(szData)))
		CC_SendMessage(id, "Veche si zashtitil edin nick sus SteamID-to si: &x03%s", szData)
	else
	{
		nvault_set(g_iVault, szAuth, szName)
		nvault_set(g_iVault, szName, szAuth)
		CC_LogMessage(id, _, "Nickut &x03%s &x01e uspeshno zashtiten sus SteamID &x04%s", szName, szAuth)
		remove_task(id + MSG_TASK)
	}

	return PLUGIN_HANDLED
}

get_user_name_lower(const id, szName[], const iLen)
{
	get_user_name(id, szName, iLen)
	strtolower(szName)
}

bool:is_valid_steam(const szAuth[])
{
	if(!equali(szAuth, "STEAM_", 6) || equal(szAuth, "STEAM_ID_LAN") || equal(szAuth, "STEAM_ID_PENDING"))
		return false
	
	return true
}

[iv69]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cromchat>
#include <nvault>

new g_iVault

public plugin_init()
{
	register_plugin("Nick Protection", "1.0", "OciXCrom")
	register_clcmd("say /nick", "Cmd_Nick")
	register_clcmd("say_team /nick", "Cmd_Nick")
	g_iVault = nvault_open("NickProtection")
	CC_SetPrefix("&x04[Nick Protection]")
}

public plugin_end()
	nvault_close(g_iVault)

public client_authorized(id)
{
	new szData[35], szName[32]
	get_user_name(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szData, charsmax(szData)))
	{
		new szAuth[35]
		get_user_authid(id, szAuth, charsmax(szAuth))

		if(!equal(szAuth, szData))
			server_cmd("kick #%i ^"Tozi nick e zashtiten sus SteamID!^"", get_user_userid(id))
	}
}

public Cmd_Nick(id)
{
	new szAuth[35], szName[32]
	get_user_name(id, szName, charsmax(szName))

	if(nvault_get(g_iVault, szName, szAuth, charsmax(szAuth)))
		CC_SendMessage(id, "Tozi nick veche e zashtiten!")
	else
	{
		get_user_authid(id, szAuth, charsmax(szAuth))
		nvault_set(g_iVault, szAuth, szName)
		CC_LogMessage(id, _, "Nickut &x03%s &x01e uspeshno zashtiten sus SteamID &x04%s", szName, szAuth)
	}

	return PLUGIN_HANDLED
}

Сега точно се сетих, да попитам за една важна според мене подробност: Нали плъгина ще работи така , че:
-1.както за един Nick ще има възможен само един STEAM_ID;
-2.Така и на един STEAM_ID, ше има възможност да се регне само един Nick;
Питането ми е , за да не се навъдят лигльовци на един ЦС , да напраскат по 100 резервирани ника... ?

И ако е така, може ли, ако не е голяма трудност, при всяко влизане на нерегистриран STEAM_ID, на играча да му излиза пояснение относно това , че ще му се регне единствено ника с който е написал /"komandata" ??? Много се извинявам за нахалството ми !
Благодаря предварително !

[OciXCrom]

Редактирах кода. Направих да може само един ник, добавих съобщение при влизане, както и забрана за VALVE_ID_LAN да ползват плъгина.

[iv69]

Редактирах кода. Направих да може само един ник, добавих съобщение при влизане, както и забрана за VALVE_ID_LAN да ползват плъгина.

Благодаря !!!

Тествах кода и е направен ИДЕАЛНО !!! Всичко за което се сетих и исках е направено професионално !!!
Този плъгин ще е винаги първия, който бих слагал във всеки нов мой сървър, ако бих правил такива !!!

Просто нямам думи !!!