Код за потвърждение: Избери целия код
#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>
//#define USING_REAPI
#if defined USING_REAPI
#include <reapi>
#else
#include <stripweapons>
#endif
#define VIP_FLAG ADMIN_RESERVATION
#define HP_ON_KILL 5
#define HP_ON_HEADSHOT 10
public plugin_init()
{
register_plugin("VIP Extras", "1.0", "OciXCrom")
register_event("DeathMsg", "OnPlayerKilled", "a")
RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
}
public OnPlayerKilled()
{
new iAttacker = read_data(1), iVictim = read_data(2)
if(!is_user_alive(iAttacker) || iAttacker == iVictim || !is_plugin_admin(iAttacker))
return
set_user_health(iAttacker, (get_user_health(iAttacker) + (read_data(3) ? HP_ON_HEADSHOT : HP_ON_KILL)))
}
public OnPlayerSpawn(id)
{
if(!is_user_alive(id) || !is_plugin_admin(id))
return
#if defined USING_REAPI
rg_give_item(id, "weapon_deagle", GT_REPLACE)
#else
StripWeapons(id, Secondary)
give_item(id, "weapon_deagle")
#endif
cs_set_user_bpammo(id, CSW_DEAGLE, 35)
cs_set_user_armor(id, 100, CS_ARMOR_VESTHELM)
give_item(id, "weapon_hegrenade")
give_item(id, "weapon_flashbang")
give_item(id, "weapon_flashbang")
give_item(id, "weapon_smokegrenade")
if(cs_get_user_team(id) == CS_TEAM_CT)
give_item(id, "item_thighpack")
}
bool:is_plugin_admin(const id)
return bool:(get_user_flags(id) & VIP_FLAG)
Щом първият начин не работи, вероятно ползваш ReAPI.
Щом вторият начин не работи, вероятно не ползваш ReGameDLL.
Значи трябва да сложиш ReGameDLL (под предположение, че ползваш ReAPI).
Другият вариант е да се откажеш от тази работа - не е болка за умиране да имаш два пистолета.