Преработка на Messages плъгин добавяне на потребителска опция

[Nine Finger's]

Здравейте бихте ли преработили този плъгин да има опция потребителят да избира дали да вижда съобщенията или не.
Да се активира и деактивира с написването на командата say/chat

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <WPMGPrintChatColor>

#define PLUGIN    "Messages"
#define VERSION   "1.0"
#define AUTHOR    "hackera457 @ AMXX-bg.Info"

#define DELAY_MESSAGES_TIME   10.0

new Array:g_aMessages

public plugin_init()
{
	register_plugin(PLUGIN,VERSION,AUTHOR)
	
	g_aMessages = ArrayCreate(128,1)
	
	LoadFile()
}

public  client_authorized(id)
{
	set_task(DELAY_MESSAGES_TIME, "DisplayMessage",id, .flags = "b")
}


public DisplayMessage(id)
{
	if(!is_user_connected(id) || is_user_bot(id) || is_user_hltv(id))
		return
	
	new szMessage[256], iArraySize, iRandom
	
	iArraySize = ArraySize(g_aMessages)
	
	if(iArraySize  < 0)
		return
		
	iRandom = random_num( 0, iArraySize - 1 )
		
	ArrayGetString(g_aMessages,iRandom, szMessage, charsmax(szMessage))
		
	PrintChatColor(id,PRINT_COLOR_GREY,"%s", szMessage)
	
}

public plugin_end()
{
	ArrayDestroy(g_aMessages)
}


LoadFile()
{
	new szFileName[256], iFilePointer
	
	get_configsdir(szFileName,charsmax(szFileName))
	add(szFileName,charsmax(szFileName),"/Messages.ini")
	
	iFilePointer = fopen(szFileName,"rt")
	
	if(!iFilePointer)
		return
		
	new szData[128]
		
	while(!feof(iFilePointer))
	{
		fgets(iFilePointer, szData,charsmax(szData))
		trim(szData)
		
		if(szData[0] == EOS || szData[0] == ';' || szData[0] == '#' || (szData[0] == '/' && szData[1] == '/'))
			continue
			
		ArrayPushString(g_aMessages, szData)

	}
	
	fclose(iFilePointer)
	
}

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <WPMGPrintChatColor>

#define PLUGIN    "Messages"
#define VERSION   "1.0"
#define AUTHOR    "hackera457 @ AMXX-bg.Info"

#define DELAY_MESSAGES_TIME   10.0

#if !defined MAX_NAME_LENGTH
const MAX_NAME_LENGTH = 32
#endif

new Array:g_aMessages
new bool:g_bEnabled[MAX_PLAYERS + 1] = {true, ...}

public plugin_init()
{
	register_plugin(PLUGIN,VERSION,AUTHOR)

	register_clcmd("say /chat", "Cmd_Toggle")
	register_clcmd("say_team /chat", "Cmd_Toggle")
	
	g_aMessages = ArrayCreate(128,1)
	
	LoadFile()
}

public  client_authorized(id)
{
	g_bEnabled[id] = true
	set_task(DELAY_MESSAGES_TIME, "DisplayMessage",id, .flags = "b")
}

public Cmd_Toggle(id)
{
	g_bEnabled[id] = !g_bEnabled[id]
	PrintChatColor(id, PRINT_COLOR_GREY, "Messages %s", g_bEnabled[id] ? "enabled" : "disabled")
	return PLUGIN_HANDLED
}


public DisplayMessage(id)
{
	if(!is_user_connected(id) || !g_bEnabled[id] || is_user_bot(id) || is_user_hltv(id))
		return
	
	new szMessage[256], iArraySize, iRandom
	
	iArraySize = ArraySize(g_aMessages)
	
	if(iArraySize  < 0)
		return
		
	iRandom = random_num( 0, iArraySize - 1 )
		
	ArrayGetString(g_aMessages,iRandom, szMessage, charsmax(szMessage))
		
	PrintChatColor(id,PRINT_COLOR_GREY,"%s", szMessage)
	
}

public plugin_end()
{
	ArrayDestroy(g_aMessages)
}


LoadFile()
{
	new szFileName[256], iFilePointer
	
	get_configsdir(szFileName,charsmax(szFileName))
	add(szFileName,charsmax(szFileName),"/Messages.ini")
	
	iFilePointer = fopen(szFileName,"rt")
	
	if(!iFilePointer)
		return
		
	new szData[128]
		
	while(!feof(iFilePointer))
	{
		fgets(iFilePointer, szData,charsmax(szData))
		trim(szData)
		
		if(szData[0] == EOS || szData[0] == ';' || szData[0] == '#' || (szData[0] == '/' && szData[1] == '/'))
			continue
			
		ArrayPushString(g_aMessages, szData)

	}
	
	fclose(iFilePointer)
	
}

[Nine Finger's]

Благодаря, всичко е перфектно, може да заключвате темата.