плъгин за Double AWP damage

[JBBM~ The House123]

Здравейте трябва ми плъгин когато направиш 11 поредни кила да ти дава AWP което да взима двойно XP и когато направят 11 кила да им излиза меню дали искат да вземат авп-то

пример:
искате ли да вземете AWP-то
1.Да
2.Не

[JBBM~ The House123]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

Някой?

[Fatall]

МНЕНИЕТО Е СКРИТО ОТ СТРАНА НА МОДЕРАТОР! ЦЪКНИ ВЪРХУ ЛЕНТАТА ЗА ДА ГО ПРЕГЛЕДАШ.

Имаш бутон избутай не спами излишно някой ако има свободно време ще ти го направи

[TheRedShoko]

За какво XP става дума? Никога не давате описателна информация и препирате да се бърза...

[JackEyedJones]

За какво XP става дума? Никога не давате описателна информация и препирате да се бърза...

HP - Двойната щета да взема двойно HP (кръв).

[TheRedShoko]

ХР - experience points
HP - health points

Ходи гадай...

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

const KILLS_NEEDED = 11
const DMG_MULTIPLIER = 2

new g_iKills[33], g_bHasAWP[33], g_iMenu

public plugin_init()
{
	register_plugin("AWP On X Kills", "1.0", "OciXCrom")
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1)
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0)
	register_event("DeathMsg", "OnPlayerKilled", "a")
	
	g_iMenu = menu_create("Dali iskash bezplatno \rAWP\y?", "MenuHandler")
	menu_additem(g_iMenu, "Da")
	menu_additem(g_iMenu, "Ne")
}

public OnPlayerSpawn(id)
{
	g_iKills[id] = 0
	g_bHasAWP[id] = false
}
	
public OnPlayerKilled()
{
	new iAttacker = read_data(1)
	
	if(is_user_alive(iAttacker) && ++g_iKills[iAttacker] == KILLS_NEEDED)
		menu_display(iAttacker, g_iMenu)
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!is_user_alive(iAttacker) || !is_user_alive(iVictim) || !g_bHasAWP[iAttacker])
		return
	
	SetHamParamFloat(4, fDamage * DMG_MULTIPLIER)
}

public MenuHandler(id, iMenu, iItem)
{
	if(is_user_alive(id) && !iItem)
	{
		give_item(id, "weapon_awp")
		cs_set_user_bpammo(id, CSW_AWP, 30)
		g_bHasAWP[id] = true
	}
}

[JackEyedJones]

Хубаво е когато дава оръжието да strip-ва другите оръжия на играча, понеже в този вид ще бие 2х damage и с други оръжия които вземе или има в него. Пример, ако има M4A1 и му даде awp-то.
И при направата на damage в PreTakeDamage да индикира дали damage-a е от AWP-то, ако все пак не се strip-ват оръжията.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>

const KILLS_NEEDED = 11;
const DMG_MULTIPLIER = 2;

new g_iKills[33], g_bHasAWP[33], g_iMenu;

public plugin_init()
{
	register_plugin("AWP On X Kills", "1.0", "OciXCrom");
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1);
	RegisterHam(Ham_TakeDamage, "player", "PreTakeDamage", 0);
	register_event("DeathMsg", "OnPlayerKilled", "a");
	
	g_iMenu = menu_create("Dali iskash bezplatno \rAWP\y?", "MenuHandler");
	menu_additem(g_iMenu, "Da");
	menu_additem(g_iMenu, "Ne");
}

public OnPlayerSpawn(id)
{
	g_iKills[id] = 0;
	g_bHasAWP[id] = false;
}
	
public OnPlayerKilled()
{
	static iAttacker;
	iAttacker = read_data(1);

	if(g_bHasAWP[iAttacker])
		return;
	
	if(is_user_alive(iAttacker) && ++g_iKills[iAttacker] == KILLS_NEEDED)
	{
		if(!user_has_weapon(iAttacker, CSW_AWP)) menu_display(iAttacker, g_iMenu)
		else 
		{
			client_print(iAttacker, print_chat, "You have AWP.");
			g_iKills[iAttacker] = 0;
		}
	}
}

public PreTakeDamage(iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits)
{
	if(!is_user_alive(iAttacker) || !is_user_alive(iVictim) || !g_bHasAWP[iAttacker])
		return;
	
	SetHamParamFloat(4, fDamage * DMG_MULTIPLIER);
}

public MenuHandler(id, iMenu, iItem)
{
	if(is_user_alive(id) && !iItem)
	{
		strip_user_weapons(id);
		give_item(id, "weapon_awp");
		cs_set_user_bpammo(id, CSW_AWP, 30);
		g_bHasAWP[id] = true;
	}
}