Проблем със вип плъгин спира сървъра.

Мнение от **sf4n** » 15 Май 2020, 23:53

Промени целия public umrql() така

public umrql ( )
{
	new ubiec = read_data ( 1 )
	new umreliq = read_data ( 2 )
	new glava = read_data ( 3 )
	
	if ( ubiec == umreliq )
	return PLUGIN_HANDLED
	if(access(ubiec, VIP_FLAG))
	{
	    if (is_user_connected(ubiec) && glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+800)
	    }
	    else if ( !glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+500)
	    }
	}
	return PLUGIN_CONTINUE
}

Мнение от **devilchy** » 16 Май 2020, 00:02

Пак крашва само че този път не изкара грешки в лога...

atmax написа: ↑15 Май 2020, 17:12 То ясно че "debug" ще оправи грешката в "logs" която излиза но въпроса е защо излиза?
Пробвай така:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <amxmisc>
#include <hamsandwich>
#include <stripweapons>

#define MOTD_FILE "vip.txt"
#define VIP_FLAG ADMIN_LEVEL_F
new Float:g_iTime = 0.1

public plugin_init()
{
    register_plugin("VIP Extras", "1.0", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", true)
    
    register_event("DeathMsg", "umrql", "a" );
    register_clcmd("say /vip", "ShowMotd")
    register_clcmd("say_team /vip", "ShowMotd")
    register_clcmd("say /vips", "ShowMotd")
    register_clcmd("say_team /vips", "ShowMotd")
}

public OnPlayerSpawn(id)
{
    if(is_user_alive(id))
    {
        if(access(id, VIP_FLAG))
        {
            StripWeapons(id, Secondary)
            give_item(id, "weapon_hegrenade")
            give_item(id, "weapon_flashbang")
            give_item(id, "weapon_flashbang")
            give_item(id, "weapon_smokegrenade")
            give_item(id, "weapon_deagle")
            cs_set_user_bpammo(id, CSW_DEAGLE, 35)
            set_user_health(id, get_user_health(id) +10)
            cs_set_user_armor(id,100,CS_ARMOR_KEVLAR)
        }
    }
}
public umrql ( )
{
	new ubiec = read_data ( 1 )
	new umreliq = read_data ( 2 )
	new glava = read_data ( 3 )
	
	if ( ubiec == umreliq )
	return PLUGIN_HANDLED
	if(access(ubiec, VIP_FLAG))
	{
	    if (is_user_connected(ubiec) && glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+800)
	    }
	    else if ( !glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+500)
	    }
	}
	return PLUGIN_CONTINUE
}
public ShowMotd(id)
{
    show_motd(id, MOTD_FILE)
    return PLUGIN_HANDLED
}
public ShowMenu(id)
{
    static szItem[32], iPlayers[32], iPnum, iMenu, i, iPlayer
    get_players(iPlayers, iPnum)
    iMenu = menu_create("", "MenuHandler")
    
    for(i = 0; i < iPnum; i++)
    {
        iPlayer = iPlayers[i]
        
        if(is_user_vip(iPlayer))
        {
            get_user_name(iPlayer, szItem, charsmax(szItem))
            menu_additem(iMenu, szItem)
        }
    }
    
    formatex(szItem, charsmax(szItem), "\r%i \yVIPs Online\d", menu_items(iMenu))
    menu_setprop(iMenu, MPROP_TITLE, szItem)
    menu_display(id, iMenu)
    return PLUGIN_HANDLED
}

public MenuHandler(id, iMenu, iItem)
{
    menu_destroy(iMenu)
    return PLUGIN_HANDLED
}
public client_putinserver(id)
{
	if(!access(id, VIP_FLAG))
	{
	    if(is_happy_hour(0, 8))
	    set_task(Float:g_iTime, "set_freevip", id)
	}
	return PLUGIN_HANDLED
}

public set_freevip(id)
	set_user_flags(id, VIP_FLAG)
	
bool:is_happy_hour(const iStart, const iEnd)
{
    static iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour < iEnd))
}

bool:is_user_vip(id)
    return bool:(get_user_flags(id) & VIP_FLAG)

П.П. Тествай плъгина дали ще работи така, защото и аз не съм голям професионалист, просто се опитвам да помогна с това което знам :Д
Всъщност сега се сетих, че когато ползваш фунцкия в която даваш пари на убиец при убийство винаги трябва да провериш дали е в съвъра с проверката is_user_connected добавих я и вече не би трябвало да хвърля тая грешка в logs пробвай плъгина!

Мнение от **atmax** » 16 Май 2020, 00:45

Трябва да се добави проверката и в следващото условие сега съм от телефон но сутринта може и да го направя, ако погледнеш разликата между двата плъгина ще разбереш какво да добавиш.

Мнение от **devilchy** » 16 Май 2020, 01:16

Пак крашна явно този плъгин няма да се оправи ...

sf4n написа: ↑15 Май 2020, 23:53 Промени целия public umrql() така

Код за потвърждение: Избери целия код

public umrql ( )
{
	new ubiec = read_data ( 1 )
	new umreliq = read_data ( 2 )
	new glava = read_data ( 3 )
	
	if ( ubiec == umreliq )
	return PLUGIN_HANDLED
	if(access(ubiec, VIP_FLAG))
	{
	    if (is_user_connected(ubiec) && glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+800)
	    }
	    else if ( !glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+500)
	    }
	}
	return PLUGIN_CONTINUE
}

Мнение от **atmax** » 16 Май 2020, 09:17

Код за потвърждение: Избери целия код

public umrql ( )
{
	new ubiec = read_data ( 1 )
	new umreliq = read_data ( 2 )
	new glava = read_data ( 3 )
	
	if ( ubiec == umreliq )
	return PLUGIN_HANDLED
	if(access(ubiec, VIP_FLAG))
	{
	    if (is_user_connected(ubiec) && glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+800)
	    }
	    else if (is_user_connected(ubiec) && !glava ) 
	    {
	        cs_set_user_money(ubiec, cs_get_user_money(ubiec)+500)
	    }
	}
	return PLUGIN_CONTINUE
}

Както обещах ето ти го с още една проверка в следващото условие пробвай така да видим дали ще крашне

Мнение от **devilchy** » 16 Май 2020, 14:35

Краша със сигурност не е от това но пак крашва, то крашва даже и с този

Код за потвърждение: Избери целия код

 #include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>
#include <stripweapons>

#define MOTD_FILE "vip.txt"
#define VIP_FLAG ADMIN_RESERVATION
#define VIP_HEALTH 110
#define VIP_ARMOR 100
#define FREE_VIP_START 0
#define FREE_VIP_END 8

public plugin_init()
{
    register_plugin("VIP Extras", "1.1", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", true)

    register_clcmd("say /vip", "ShowMotd")
    register_clcmd("say_team /vip", "ShowMotd")
    register_clcmd("say /vips", "ShowMenu")
    register_clcmd("say_team /vips", "ShowMenu")
}

public OnPlayerSpawn(id)
{
    if(!is_user_alive(id) || !is_user_vip(id))
        return

    StripWeapons(id, Secondary)
    give_item(id, "weapon_hegrenade")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_smokegrenade")

    give_item(id, "weapon_deagle")
    cs_set_user_bpammo(id, CSW_DEAGLE, 35)
    set_user_health(id, VIP_HEALTH)
    set_user_armor(id, VIP_ARMOR)
}

public ShowMotd(id)
{
    show_motd(id, MOTD_FILE)
    return PLUGIN_HANDLED
}

public ShowMenu(id)
{
    static szItem[32], iPlayers[32], iPnum, iMenu, i, iPlayer
    get_players(iPlayers, iPnum)
    iMenu = menu_create("", "MenuHandler")

    for(i = 0; i < iPnum; i++)
    {
        iPlayer = iPlayers[i]

        if(is_user_vip(iPlayer))
        {
            get_user_name(iPlayer, szItem, charsmax(szItem))
            menu_additem(iMenu, szItem)
        }
    }

    formatex(szItem, charsmax(szItem), "\r%i \yVIPs Online\d", menu_items(iMenu))
    menu_setprop(iMenu, MPROP_TITLE, szItem)
    menu_display(id, iMenu)
    return PLUGIN_HANDLED
}

public MenuHandler(id, iMenu, iItem)
{
    menu_destroy(iMenu)
    return PLUGIN_HANDLED
}

bool:is_current_time(const iStart, const iEnd)
{
    static iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour <= iEnd))
}

bool:is_user_vip(id)
    return ((get_user_flags(id) & VIP_FLAG != 0) || is_current_time(FREE_VIP_START, FREE_VIP_END))

Във предната тема ocixcrom ми го е дал тука даже няма функцията "umrql" нещо друго му има ...

Мнение от **sf4n** » 16 Май 2020, 14:45

Пак повтарям, че от 20 плъгина ти мислиш този за виновния за крашовете.... Прегледай си хубаво конзолата няма как да не пише нищо като крашва сървъра.

YouTube · Мнение от **OciXCrom** » 16 Май 2020, 15:11

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <fun>
#include <hamsandwich>
#include <reapi>

#define MOTD_FILE "vip.txt"
#define VIP_FLAG ADMIN_RESERVATION
#define VIP_HEALTH 110
#define VIP_ARMOR 100
#define FREE_VIP_START 0
#define FREE_VIP_END 8

public plugin_init()
{
    register_plugin("VIP Extras", "1.1", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", true)

    register_clcmd("say /vip", "ShowMotd")
    register_clcmd("say_team /vip", "ShowMotd")
    register_clcmd("say /vips", "ShowMenu")
    register_clcmd("say_team /vips", "ShowMenu")
}

public OnPlayerSpawn(id)
{
    if(!is_user_alive(id) || !is_user_vip(id))
        return

    rg_remove_items_by_slot(id, PISTOL_SLOT)
    give_item(id, "weapon_hegrenade")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_flashbang")
    give_item(id, "weapon_smokegrenade")

    give_item(id, "weapon_deagle")
    cs_set_user_bpammo(id, CSW_DEAGLE, 35)
    set_user_health(id, VIP_HEALTH)
    set_user_armor(id, VIP_ARMOR)
}

public ShowMotd(id)
{
    show_motd(id, MOTD_FILE)
    return PLUGIN_HANDLED
}

public ShowMenu(id)
{
    new szItem[32], iPlayers[32], iPnum
    get_players(iPlayers, iPnum)

    new iMenu = menu_create("Menu", "MenuHandler")

    for(new i, iPlayer; i < iPnum; i++)
    {
        iPlayer = iPlayers[i]

        if(is_user_vip(iPlayer))
        {
            get_user_name(iPlayer, szItem, charsmax(szItem))
            menu_additem(iMenu, szItem)
        }
    }

    formatex(szItem, charsmax(szItem), "\r%i \yVIPs Online\d", menu_items(iMenu))
    menu_setprop(iMenu, MPROP_TITLE, szItem)
    menu_display(id, iMenu)
    return PLUGIN_HANDLED
}

public MenuHandler(id, iMenu, iItem)
{
    menu_destroy(iMenu)
    return PLUGIN_HANDLED
}

bool:is_current_time(const iStart, const iEnd)
{
    new iHour; time(iHour)
    return bool:(iStart < iEnd ? (iStart <= iHour < iEnd) : (iStart <= iHour || iHour <= iEnd))
}

bool:is_user_vip(id)
    return ((get_user_flags(id) & VIP_FLAG != 0) || is_current_time(FREE_VIP_START, FREE_VIP_END))

Мнение от **devilchy** » 16 Май 2020, 19:20

@ociXCrom категорично има ефект тествах го около 2 часа и няма проблем, Благодаря можете да лок.

Кой е на линия