Проблем с Admin Model, скиновете не се показват

Въпроси и проблеми свързани с AMXModX.
Аватар
stoyanof
Извън линия
Потребител
Потребител
Мнения: 47
Регистриран на: 22 Юни 2017, 18:43
Се отблагодари: 2 пъти
Получена благодарност: 7 пъти

Проблем с Admin Model, скиновете не се показват

Мнение от stoyanof » 03 Мар 2019, 15:28

Здравейте,

Имам следния проблем, когато вляза в сървъра скиновете ми се свалят от svdl, но не се показват по време на игра. :think:

Код за потвърждение: Избери целия код

/*########################################################################## 
## 
## -- www.SteamTools.net 
##      ___   _____       ___  ___   _   __   _            ___  ___   _____   _      
##     /   | |  _  \     /   |/   | | | |  \ | |          /   |/   | |  _  \ | |      
##    / /| | | | | |    / /|   /| | | | |   \| |         / /|   /| | | | | | | |      
##   / / | | | | | |   / / |__/ | | | | | |\   |        / / |__/ | | | | | | | |      
##  / /  | | | |_| |  / /       | | | | | | \  |       / /       | | | |_| | | |___  
## /_/   |_| |_____/ /_/        |_| |_| |_|  \_|      /_/        |_| |_____/ |_____| 
##                                                        
##          |__                   |__  o _|_   ___   __ __  o |__,  ___  
##      --  |__) (__|     (__(__( |  ) |  |_, (__/_ |  )  ) | |  \ (__/_ 
##                  |                                                    
## 
##   Originated as a simple idea back in 2004, it was forgotten due to 
## lack of my 'Small' coding skills. However I have progressed in recent 
## months and somehow crossed that old post with this concept in it. So 
## naturally I challenged myself to see if I could do it, and voila! I 
## could :) 
## 
##   Once you join, you play a normal person for the first round, and for 
## all remaining rounds your CT or TE models are custom. They now read 
## "ADMIN" on front and back, and also have small "A" patches on the arms. 
## I designed these models myself, it's very easy, just bring the textures 
## into photoshop, tweak out, and replace. 
## 
##   Enjoy! 
## 
## 
## CHANGELOG 
##------------------------------------------------------------------------ 
## 2) v1.1.1 - Fixed missing event 
## 1) v1.1.0 - Fixed VIP and other model bugs 
## 
## 
## INSTALLATION 
##------------------------------------------------------------------------ 
## 1) Unzip (which you may have done already) 
## 2) Place 'amx_adminmodel.amxx' in 'cstrike/addons/amxmodx/plugins' 
## 3) Add a line in 'configs/plugins.ini' containing 'amx_adminmodel.amxx' 
## 4) Put the 'admin_ct' and 'admin_te' folders into 'cstrike/models' folder 
## 5) -- Visit www.SteamTools.net and enjoy your new plugin! 
## 
## 
## 
## THE CVARs 
##------------------------------------------------------------------------ 
## 
## No CVARs for this plugin :) 
## 
## 
##########################################################################*/	


#include <amxmodx>
#include <amxmisc>
#include <cstrike>

public plugin_init() {
        register_plugin("AMX Admin Model", "1.1.1", "whitemike")
        register_event("ResetHUD", "resetModel", "b")
        return PLUGIN_CONTINUE
}

public plugin_precache() {
        precache_model("models/player/csbulgaria/admin_ct/admin_ct.mdl")
        precache_model("models/player/csbulgaria/admin_te/admin_te.mdl")

        return PLUGIN_CONTINUE
}

public resetModel(id, level, cid) {
        if (get_user_flags(id) & ADMIN_KICK) {
                new CsTeams:userTeam = cs_get_user_team(id)
                if (userTeam == CS_TEAM_T) {
                        cs_set_user_model(id, "admin_te")
                }
                else if(userTeam == CS_TEAM_CT) {
                        cs_set_user_model(id, "admin_ct")
                }
                else {
                        cs_reset_user_model(id)
                }
        }

        return PLUGIN_CONTINUE
}
Последно промяна от stoyanof на 03 Мар 2019, 15:34, променено общо 1 път.

Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Проблем с Admin Model

Мнение от OciXCrom » 03 Мар 2019, 15:33

Оправи заглавието на темата като обясниш какъв точно е проблемът.

Пътят до моделите ти е невалиден. Моделите за играчи трябва да се намират в models/player/ime_na_modela/ime_na_modela.mdl.

Плъгинът, който ползваш, също е зле. Ползвай това:

Код за потвърждение: Избери целия код

/*
_____/\\\\\\\\\_____/\\\\____________/\\\\__/\\\_______/\\\__/\\\_______/\\\________________/\\\\\\\\\\\\\_______/\\\\\\\\\\\\_        
 ___/\\\\\\\\\\\\\__\/\\\\\\________/\\\\\\_\///\\\___/\\\/__\///\\\___/\\\/________________\/\\\/////////\\\___/\\\//////////__       
  __/\\\/////////\\\_\/\\\//\\\____/\\\//\\\___\///\\\\\\/______\///\\\\\\/__________________\/\\\_______\/\\\__/\\\_____________      
   _\/\\\_______\/\\\_\/\\\\///\\\/\\\/_\/\\\_____\//\\\\__________\//\\\\_______/\\\\\\\\\\\_\/\\\\\\\\\\\\\\__\/\\\____/\\\\\\\_     
    _\/\\\\\\\\\\\\\\\_\/\\\__\///\\\/___\/\\\______\/\\\\___________\/\\\\______\///////////__\/\\\/////////\\\_\/\\\___\/////\\\_    
     _\/\\\/////////\\\_\/\\\____\///_____\/\\\______/\\\\\\__________/\\\\\\___________________\/\\\_______\/\\\_\/\\\_______\/\\\_   
      _\/\\\_______\/\\\_\/\\\_____________\/\\\____/\\\////\\\______/\\\////\\\_________________\/\\\_______\/\\\_\/\\\_______\/\\\_  
       _\/\\\_______\/\\\_\/\\\_____________\/\\\__/\\\/___\///\\\__/\\\/___\///\\\_______________\/\\\\\\\\\\\\\/__\//\\\\\\\\\\\\/__ 
        _\///________\///__\///______________\///__\///_______\///__\///_______\///________________\/////////////_____\////////////____
					__/\\\________/\\\_______________________________/\\\______________________________________                                            
					 _\/\\\_______\/\\\______________________________\/\\\______________________________________                                           
					  _\/\\\_______\/\\\______________________________\/\\\______________________________________                                          
					   _\/\\\\\\\\\\\\\\\__/\\\____/\\\_____/\\\\\\\\__\/\\\__________/\\\____/\\\_____/\\\\\\\\__                                         
					    _\/\\\/////////\\\_\/\\\___\/\\\___/\\\/////\\\_\/\\\\\\\\\\__\/\\\___\/\\\___/\\\/////\\\_                                        
					     _\/\\\_______\/\\\_\/\\\___\/\\\__/\\\\\\\\\\\__\/\\\/////\\\_\/\\\___\/\\\__/\\\\\\\\\\\__                                       
					      _\/\\\_______\/\\\_\/\\\___\/\\\_\//\\///////___\/\\\___\/\\\_\/\\\___\/\\\_\//\\///////___                                      
					       _\/\\\_______\/\\\_\//\\\\\\\\\___\//\\\\\\\\\\_\/\\\___\/\\\_\//\\\\\\\\\___\//\\\\\\\\\\_                                     
					        _\///________\///___\/////////_____\//////////__\///____\///___\/////////_____\//////////__
*/

#include <amxmodx>

/* Common include libraries */
#include <fakemeta>
#include <hamsandwich>

#define VERSION "1.0-Huehue"

// Comment this line If you don't need delayed player model set.
#define DELAYED_SPAWN
#if defined DELAYED_SPAWN
	// After how many seconds player model will be changed.
	#define DELAY_SPAWN_FREQ 	1.5
#endif // DELAYED_SPAWN

#define ADMIN_ACCESS 	ADMIN_LEVEL_C
#define TERR_MODEL 	"AdminTE"
#define CT_MODEL 	"AdminCT"

new g_szModel[MAX_PLAYERS + 1][MAX_NAME_LENGTH];

public plugin_init()
{
	register_plugin("Admin Models", VERSION, "AMXX-BG PawnTeam");
	register_cvar("admin_models", VERSION, FCVAR_SERVER | FCVAR_SPONLY);
	set_cvar_string("admin_models", VERSION);
	
	register_forward(FM_SetClientKeyValue, "FM__SetClientKeyValue");
	register_message(get_user_msgid("ClCorpse"), "Message_ClCorpse");
	
	RegisterHam(Ham_Spawn, "player", "CBasePlayer_Ham_Spawn", 1);
}

public plugin_precache()
{
	precache_player_model(TERR_MODEL);
	precache_player_model(CT_MODEL);
}

public client_connect(id)
{
	g_szModel[id][0] = EOS;
}

public CBasePlayer_Ham_Spawn(id)
{
	if (!is_user_alive(id))
	{
		return;
	}

	if (get_user_flags(id) & ADMIN_ACCESS)
	{
		#if defined DELAYED_SPAWN
		set_task(DELAY_SPAWN_FREQ, "Delayed_Model_Attach", id);
		#else
		SetUserModel(id, get_user_team(id) == 1 ? TERR_MODEL : CT_MODEL);
		set_user_info(id, "model", g_szModel[id]);
		#endif
	}
	else
	{
		g_szModel[id][0] = EOS;
		set_user_info(id, "model", "");
	}
}

#if defined DELAYED_SPAWN
public Delayed_Model_Attach(id)
{
	if (!is_user_alive(id))
	{
		return;
	}

	SetUserModel(id, get_user_team(id) == 1 ? TERR_MODEL : CT_MODEL);
	set_user_info(id, "model", g_szModel[id]);
}
#endif // DELAYED_SPAWN

public FM__SetClientKeyValue(id, const szInfoBuffer[], const szKey[], const szValue[])
{
	if (g_szModel[id][0] && equal(szKey, "model") && !equal(szValue, g_szModel[id]))
	{
		set_user_info(id, "model", g_szModel[id]);
		return FMRES_SUPERCEDE;
	}
	return FMRES_IGNORED;
}
	
public Message_ClCorpse()
{
	new id = get_msg_arg_int(12);
		    
	if (g_szModel[id][0])
	{
		set_msg_arg_string(1, g_szModel[id]);
	}
}
stock SetUserModel(id, szModelName[])
{
	return copy(g_szModel[id], charsmax(g_szModel), szModelName);
}

// Credits to OciXCrom
stock precache_player_model(const name[], &id = 0)
{
	new model[128];
	formatex(model, charsmax(model), "models/player/%s/%sT.mdl", name, name);

	if(file_exists(model))
		id = precache_generic(model);

	static const extension[] = "T.mdl";
	#pragma unused extension

	copy(model[strlen(model) - charsmax(extension)], charsmax(model), ".mdl");
	return precache_model(model);
}

Аватар
stoyanof
Извън линия
Потребител
Потребител
Мнения: 47
Регистриран на: 22 Юни 2017, 18:43
Се отблагодари: 2 пъти
Получена благодарност: 7 пъти

Проблем с Admin Model, скиновете не се показват

Мнение от stoyanof » 03 Мар 2019, 15:40

когато пътя е

Код за потвърждение: Избери целия код

        precache_model("models/player/admin_ct/admin_ct.mdl")
        precache_model("models/player/admin_te/admin_te.mdl")
ми сваля съвсем друг скин за CT от svdl на gameservers, има ли начин задам на плъгина от къде точно да сваля скиновете или просто трябва да ги накарам да ми преименуват директориите и да прекомпилирам плъгина?

Аватар
hackera457
Извън линия
Модератор
Модератор
Мнения: 768
Регистриран на: 01 Ное 2016, 09:46
Местоположение: София
Се отблагодари: 1 път
Получена благодарност: 124 пъти
Обратна връзка:

Проблем с Admin Model, скиновете не се показват

Мнение от hackera457 » 03 Мар 2019, 16:09

stoyanof написа: 03 Мар 2019, 15:40 когато пътя е

Код за потвърждение: Избери целия код

        precache_model("models/player/admin_ct/admin_ct.mdl")
        precache_model("models/player/admin_te/admin_te.mdl")
ми сваля съвсем друг скин за CT от svdl на gameservers, има ли начин задам на плъгина от къде точно да сваля скиновете или просто трябва да ги накарам да ми преименуват директориите и да прекомпилирам плъгина?
Възможно е това, зависи какво има на този sv_downloadurl. Препоръката е да си направите ваш собствен, да знаете че на него има само вашите ресурси
Моите плъгини

Код за потвърждение: Избери целия код

#include <hambeer>

RegisterHamBeer(HamBeer_Spawn, "player", "GivePlayerBeer", 1);

public GivePlayerBeer(Pl){
    if(!is_user_alive(Pl)){
        ham_give_beer(Pl, 5)
        client_print(Pl, print_chat, "Go Go Go"){
}  


Аватар
OciXCrom
Извън линия
Администратор
Администратор
Мнения: 7206
Регистриран на: 06 Окт 2016, 19:20
Местоположение: /resetscore
Се отблагодари: 117 пъти
Получена благодарност: 1295 пъти
Обратна връзка:

Проблем с Admin Model, скиновете не се показват

Мнение от OciXCrom » 03 Мар 2019, 17:09

Много ясно като всеки ползва тези имена. Логично е, че трябва да сложиш уникални имена на моделите за играчите да могат да ги изтеглят когато влезнат в сървъра. 50% от играчите вече имат модели с такива имена в играта им, така че няма да изтеглят твоите от сървъра - смени имената.

Публикувай отговор
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Поддръжка / Помощ”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 6 госта