Gametracker Plugin Problem

[lantimilan]

Hello OciXCrom i download your plugin but i edit i change gt link i set gametracker.rs because it have more fix data,time players but i have one problem i dont know why grahipc not open good have some problems , you can see photo how show https://i.imgur.com/KMdggsD.png
Do you know why problem have

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>

#define PLUGIN_VERSION "2.0"

new g_iSayText
new g_szPage[256]
new const g_szPrefix[] = "!n[!gGametracker!n]"

public plugin_init()
{
	register_plugin("Gametracker", PLUGIN_VERSION, "OciXCrom")
	register_cvar("CRXGametracker", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	
	register_clcmd("say /oret", "CmdOpenGametracker")
	register_clcmd("say_team /oret", "CmdOpenGametracker")
	register_clcmd("say /linkioreve", "CmdShowLink")
	register_clcmd("say_team /linkioreve", "CmdShowLink")
	register_concmd("amx_gametracker", "CmdPlayerGametracker", ADMIN_ALL, "<nick|#userid> <link/open> -- Get player's Gametracker page")
	
	new szIP[22]
	get_user_ip(0, szIP, charsmax(szIP))
	formatex(g_szPage, charsmax(g_szPage), "http://www.gametracker.rs/server_players/<name>/%s/", szIP)
	g_iSayText = get_user_msgid("SayText")
}

public CmdOpenGametracker(id)
{
	show_gametracker_motd(id, id)
	return PLUGIN_HANDLED
}

public CmdShowLink(id)
{
	new szPage[256]
	get_gametracker_link(id, szPage, charsmax(szPage))
	ColorChat(id, "!tFaqja Gametracker tuaj !neshte: !g%s", szPage)
	return PLUGIN_HANDLED
}

public CmdPlayerGametracker(id, iLevel, iCid)
{
	if(!cmd_access(id, iLevel, iCid, 3))
		return PLUGIN_HANDLED
	
	new szArg[32]
	read_argv(1, szArg, charsmax(szArg))
	
	new iPlayer = cmd_target(id, szArg, 0)
	
	if(!iPlayer)
		return PLUGIN_HANDLED
		
	new szName[32], szType[5]
	get_user_name(iPlayer, szName, charsmax(szName))
	read_argv(2, szType, charsmax(szType))
	
	switch(szType[0])
	{
		case 'L', 'l':
		{
			new szPage[256]
			get_gametracker_link(iPlayer, szPage, charsmax(szPage))
			client_print(id, print_console, "%s's Gametracker faqja eshte: %s", szName, szPage)
		}
		case 'O', 'o': show_gametracker_motd(id, iPlayer)
		default: client_print(id, print_console, "* Gabim ^"%s^". Ju lutem ndiqeni kete: link/open", szType)
	}
	
	return PLUGIN_HANDLED
}
	
show_gametracker_motd(id, iPlayer)
{
	new szPage[256], szHeader[64], szName[32]
	get_gametracker_link(iPlayer, szPage, charsmax(szPage))
	get_user_name(iPlayer, szName, charsmax(szName))
	formatex(szHeader, charsmax(szHeader), "[GT] %s", szName)
	show_motd(id, szPage, szHeader)
}

get_gametracker_link(id, szPage[256], iLen)
{
	new szName[32]
	get_user_name(id, szName, charsmax(szName))
	copy(szPage, iLen, g_szPage)
	replace(szPage, iLen, "<name>", szName)
}

ColorChat(const id, const szInput[], any:...)
{
	new iPlayers[32], iCount = 1
	static szMessage[191]
	vformat(szMessage, charsmax(szMessage), szInput, 3)
	format(szMessage[0], charsmax(szMessage), "%s %s", g_szPrefix, szMessage)
	
	replace_all(szMessage, charsmax(szMessage), "!g", "^4")
	replace_all(szMessage, charsmax(szMessage), "!n", "^1")
	replace_all(szMessage, charsmax(szMessage), "!t", "^3")
	
	if(id)
		iPlayers[0] = id
	else
		get_players(iPlayers, iCount, "ch")
	
	for(new i; i < iCount; i++)
	{
		if(is_user_connected(iPlayers[i]))
		{
			message_begin(MSG_ONE_UNRELIABLE, g_iSayText, _, iPlayers[i])
			write_byte(iPlayers[i])
			write_string(szMessage)
			message_end()
		}
	}
}

[deadlylord]

It doesn't work for you, cuz your game in not payed and the scrolling doesn't work
You can use viewtopic.php?f=32&t=57 and then you have to put in the .txt file

Код за потвърждение: Избери целия код

<iframe src="http://www.gametracker.rs/server_info/93.123.18.45:27015/" width="1250" height="2500" scrolling="yes" ></iframe>

And it is going to work perfectly fine

[OciXCrom]

There's no need to use a different plugin. He can put that code in this one too.

Replace this:

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "http://www.gametracker.rs/server_players/<name>/%s/", szIP)

With this:

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "<iframe src=^"http://www.gametracker.rs/server_players/<name>/%s/^" width=^"1250^" height=^"2500^" scrolling=^"yes^" ></iframe>", szIP)

[lantimilan]

Now its okey but he show just all players time no one person , look photo : https://i.imgur.com/Cf7IE73.png

[OciXCrom]

Your link is wrong. It's gametracker.rs/player/<server ip>/<player name>, not gametracker.rs/server_players/<player name>/<server ip>. Make it like this:

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "<iframe src=^"http://www.gametracker.rs/player/%s/<name>/^" width=^"1250^" height=^"2500^" scrolling=^"yes^" ></iframe>", szIP)

[lantimilan]

Yes its okey now workig good but i have one problem can we minimize to see in direct motd not use mous to see all site same in photo : https://i.imgur.com/tJ0pIKW.png

[OciXCrom]

I don't know. Experiment with the size (width=^"1250^" height=^"2500^"). The best approach is to not use iframe at all.

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "http://www.gametracker.rs/player/%s/<name>/", szIP)

But some people won't be able to scroll.

[lantimilan]

For gametracker.rs its okey but when i try for gametracker same code not working not compile

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "<iframe src=^"http://www.gametracker.com/player/%s/<name>/^" width=^"1250^" height=^"2500^" scrolling=^"yes^" ></iframe>", szIP)

[OciXCrom]

It compiles fine for me.

[lantimilan]

Код за потвърждение: Избери целия код

formatex(g_szPage, charsmax(g_szPage), "<iframe src=^"http://www.gametracker.com/player/%s/<name>/^" width=^"1250^" height=^"2500^" scrolling=^"yes^" ></iframe>", szIP)

Try with this code ? Look : http://prntscr.com/hhq3wx