GoSpec [ /spec; /back; /change ]

[TheRedShoko]

Премини на ReAMXX, от него е. Бяха писали в една тема относно това. WaLkZ беше дал линк в чата вчера.

[WaLkZ]

[OciXCrom]

• Променен ColorChat с CromChat.
• Добавен lang файл.

[LoShIaA]

Здравейте. Днес сложих новата версия и забелязах следното като влезна с ник без права и напиша /spec, /back или /change и съобщенията не излизат ето снимка:

1.jpg (364.53 KiB) Преглеждано 4864 пъти

1.jpg (364.53 KiB) Преглеждано 4864 пъти

Когато съм с права всичко си е точно:

2.jpg (162.94 KiB) Преглеждано 4864 пъти

2.jpg (162.94 KiB) Преглеждано 4864 пъти

3.jpg (326.39 KiB) Преглеждано 4864 пъти

3.jpg (326.39 KiB) Преглеждано 4864 пъти

4.jpg (366.66 KiB) Преглеждано 4864 пъти

4.jpg (366.66 KiB) Преглеждано 4864 пъти

5.jpg (306.92 KiB) Преглеждано 4864 пъти

5.jpg (306.92 KiB) Преглеждано 4864 пъти

Може ли да се направи като се трансферираш наляво, надясно да не ти вписва умирания в статистиката?
Интересува ме понеже използвам този админ моделс https://dev-cs.ru/resources/103/extra и понякога, когато съм бил спектатор и върна с комнадата /back не винаги ми слага веднага админския скин (прави го рядко, а и също предполгам, че ако ме убият ще се оправи ведната). Кой от двата плъгина може да прави проблема? Сървъра е Respawn.

[aLbaShaRe]

Отвори ланг файла на плъгина и намери това
GOSPEC_NO_ACESS = You have no access to this command!

Направи го да изглежда така :
GOSPEC_NO_ACCESS = You have no access to this command! Изпуснал е една буква за това не изкарва събощението.

[LoShIaA]

И аз го гледах преди да пусна темата и аз съм я прескочил . Мерси

[OciXCrom]

Оправих го. За да не вписва умирания, опитай да замениш user_silentkill(id) (на две места го има), с user_kill(id, 1), обаче по този начин ще показва, че си се убил. За скина - проблемът е в другия плъгин, щом не успява да ги промени на време.

[LoShIaA]

Замених го, но сега хем показва, че се самоубивам, хем отчита и умирания пак.

[OciXCrom]

Ами толкова правилно работят въпросните функции. Остави го както беше (user_silentkill), и под него добави cs_set_user_deaths(id, cs_get_user_deaths(id) - 1).

[LoShIaA]

Супер, така работи. Сега нито показва, че умирам нито начислява умирания, но при компилация излезна едно предупреждение.
crx_gospec.sma(63) : warning 217: loose indentation - тази грешка заради някакъв TAB ли се получава?

Код за потвърждение: Избери целия код

[#include <amxmodx>
#include <cromchat>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN_VERSION "1.2"

enum _:Cvars
{
	gospec_spec_flag,
	gospec_change_flag,
	gospec_respawn
}

new g_eCvars[Cvars]

new CsTeams:g_iOldTeam[33],
	g_iSpecFlag,
	g_iChangeFlag

public plugin_init()
{
	register_plugin("GoSpec", PLUGIN_VERSION, "OciXCrom")
	register_cvar("@CRXGoSpec", PLUGIN_VERSION, FCVAR_SERVER|FCVAR_SPONLY|FCVAR_UNLOGGED)
	register_dictionary("GoSpec.txt")
	
	register_clcmd("say /spec", "GoSpec")
	register_clcmd("say /back", "GoBack")
	register_clcmd("say /change", "SwitchTeam")
	
	g_eCvars[gospec_spec_flag] = register_cvar("gospec_spec_flag", "d")
	g_eCvars[gospec_change_flag] = register_cvar("gospec_change_flag", "b")
	g_eCvars[gospec_respawn] = register_cvar("gospec_respawn", "1")
	CC_SetPrefix("&x04[&x03GoSpec&x04]")
}

public plugin_cfg()
{
	new szFlag[2]
	get_pcvar_string(g_eCvars[gospec_spec_flag], szFlag, charsmax(szFlag))
	g_iSpecFlag = szFlag[0] == EOS ? ADMIN_ALL : read_flags(szFlag)
	get_pcvar_string(g_eCvars[gospec_change_flag], szFlag, charsmax(szFlag))
	g_iChangeFlag = szFlag[0] == EOS ? ADMIN_ALL : read_flags(szFlag)
}

public GoSpec(id)
{
	if(!HasAccess(id, g_iSpecFlag))
		return PLUGIN_HANDLED
	
	new CsTeams:iTeam = cs_get_user_team(id)
		
	if(iTeam == CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_ALREADY_SPECTATOR")
	else
	{
		g_iOldTeam[id] = iTeam
		cs_set_user_team(id, CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_NOW_SPECTATOR")
		
		if(is_user_alive(id))
			user_silentkill(id)
			cs_set_user_deaths(id, cs_get_user_deaths(id) - 1)
	}
	
	return PLUGIN_HANDLED
}

public GoBack(id)
{
	if(!HasAccess(id, g_iSpecFlag))
		return PLUGIN_HANDLED
		
	if(cs_get_user_team(id) != CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_NOT_SPECTATOR")
	else
	{
		new iPlayers[32], iCT, iT
		get_players(iPlayers, iCT, "e", "CT")
		get_players(iPlayers, iT, "e", "TERRORIST")
		
		if(iCT == iT)
		{
			cs_set_user_team(id, g_iOldTeam[id])
			CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_PREVIOUS")
		}
		else
		{
			cs_set_user_team(id, iCT > iT ? CS_TEAM_T : CS_TEAM_CT)
			CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_LESS")
		}
		
		if(get_pcvar_num(g_eCvars[gospec_respawn]))
			ExecuteHamB(Ham_CS_RoundRespawn, id)
	}		
	
	return PLUGIN_HANDLED
}

public SwitchTeam(id)
{
	if(!HasAccess(id, g_iChangeFlag))
		return PLUGIN_HANDLED
		
	new CsTeams:iTeam = cs_get_user_team(id)
		
		
	if(iTeam == CS_TEAM_SPECTATOR)
		CC_SendMessage(id, "%L", id, "GOSPEC_CANT_USE")
	else
	{
		cs_set_user_team(id, cs_get_user_team(id) == CS_TEAM_CT ? CS_TEAM_T : CS_TEAM_CT)
		CC_SendMessage(id, "%L", id, "GOSPEC_TRANSFERED_TO_OPPOSITE")
		
		if(is_user_alive(id))
		{
			user_silentkill(id)
			cs_set_user_deaths(id, cs_get_user_deaths(id) - 1)
			
			if(get_pcvar_num(g_eCvars[gospec_respawn]))
				ExecuteHamB(Ham_CS_RoundRespawn, id)
		}			
	}
	
	return PLUGIN_HANDLED
}

bool:HasAccess(id, iFlag)
{
	if(iFlag == ADMIN_ALL || get_user_flags(id) & iFlag)
		return true
	else
	{
		CC_SendMessage(id, "%L", id, "GOSPEC_NO_ACCESS")
		return false
	}
	
	#if AMXX_VERSION_NUM < 183
	return false
	#endif
}
/code]