Блокиране на healing zones

[DaRk_StyLe]

Пробвай така.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <fakemeta>

new g_Forward

public plugin_precache()
{
	g_Forward = register_forward(FM_KeyValue, "Forward_KeyValue")
}

public plugin_init()
{
	unregister_forward(g_Forward, FM_KeyValue)
}

public Forward_KeyValue(Entity, KvdID)
{
	if(pev_valid(Entity))
	{
		new KeyClassName[13], KeyName[4]
		
		get_kvd(KvdID, KV_ClassName, KeyClassName, charsmax(KeyClassName))
		get_kvd(KvdID, KV_KeyName, KeyName, charsmax(KeyName))
		
		if(equal(KeyClassName, "trigger_hurt") && equal(KeyName, "dmg"))
		{
			set_kvd(0, KV_KeyName, KeyName)
			set_kvd(0, KV_Value, "0")
			set_kvd(0, KV_fHandled, 0)
			dllfunc(DLLFunc_KeyValue, Entity, 0)
			
			return FMRES_SUPERCEDE
		}
	}
	
	return FMRES_IGNORED
}

[TheRedShoko]

Забравих да напиша, че не ми трябва да се блокират постоянно, а само при определни ситуации, затова се зачудих, как да стане чрез forward-a.

[DaRk_StyLe]

Би ли ми предоставил малка карта, на която да тествам, защото всички, които намирам са огромни.

[TheRedShoko]

http://gamebanana.com/maps/176570 тази е най-малката, за която се сещам... Има ги в CT spawn.

[DaRk_StyLe]

Аналгина ми сглоби карта с отрицателен trigger_hurt и func_healthcharger. Този метод блокира даването на кръв от желаните от теб entity-та, но в случай, че изкочи entity, което искаш да дава кръв, то тогава ще се наложи да видиш какъв вид Damagebits използва и да го изключиш от забраната.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>

new Blocked[33]

public plugin_init()
{
	RegisterHam(Ham_TakeHealth, "player", "Forward_Ham_TakeHealth")
	register_clcmd("say set", "ClientCommand_Set")
}

public ClientCommand_Set(id)
{
	if(!Blocked[id])
	{
		Blocked[id] = true 
		client_print(id, print_chat, "Blocked set to true")
	}
	else 
	{
		Blocked[id] = false 
		client_print(id, print_chat, "Blocked set to false")
	}
}

public Forward_Ham_TakeHealth(id, Float:Health, Damagebits)
{
	if(Blocked[id])
	{
		return HAM_SUPERCEDE
	}
	
	return HAM_IGNORED
}

[TheRedShoko]

Бях забравил, че съществува подобен Ham forward... Благодаря ти.