Заявката за DeathRun VIP

[SkandaU]

Здравейте, трябва ми вип плъгин, който позволява на потребители с флаг Level_E да използват:

/respawn команда три пъти на рунд.
100 кръв § 100 броня (ако може да се нагласи от същия плъгин обикновенните играчи да имат 50 кръв с цел да не бъгва).
Не + флаш граната.
Лек зелен glow.
Deagle когато е терорист - 1 патрон
Когато натиснеш таб да изписва ВИП до тяхното име.

[OciXCrom]

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <amxmisc>
#include <cromchat>
#include <cstrike>
#include <fun>
#include <hamsandwich>

#define GLOW_COLOR 16, 128, 42

const VIP_FLAG = ADMIN_LEVEL_E;
const PLAYER_HEALTH = 50;
const VIP_HEALTH = 50;
const VIP_ARMOR = 50;
const GLOW_BRIGHTNESS = 40;
const MAX_RESPAWNS = 3;

enum
{
	SCOREATTRIB_ARG_PLAYERID = 1,
	SCOREATTRIB_ARG_FLAGS
}

enum (<<= 1)
{
	SCOREATTRIB_FLAG_NONE = 0,
	SCOREATTRIB_FLAG_DEAD = 1,
	SCOREATTRIB_FLAG_BOMB,
	SCOREATTRIB_FLAG_VIP
}

new g_iRespawns[33];

public plugin_init()
{
	register_plugin("Deathrun VIP", "1.0", "OciXCrom");
	RegisterHam(Ham_Spawn, "player", "OnPlayerSpawn", 1);
	register_message(get_user_msgid("ScoreAttrib"), "OnScoreAttrib");
	register_logevent("OnRoundStart", 2, "0=World triggered", "1=Round_Start");
	register_clcmd("say /respawn", "Cmd_Respawn", VIP_FLAG);
	register_clcmd("say_team /respawn", "Cmd_Respawn", VIP_FLAG);
	CC_SetPrefix("&x04[VIP]");
}

public client_putinserver(id)
	g_iRespawns[id] = 0;

public Cmd_Respawn(id, iLevel, iCid)
{
	if(cmd_access(id, iLevel, iCid, 1))
	{
		if(g_iRespawns[id] < MAX_RESPAWNS)
		{
			if(is_user_alive(id))
			{
				g_iRespawns[id]++;
				ExecuteHamB(Ham_CS_RoundRespawn, id);
			}
			else CC_SendMessage(id, "You can't use this command while you're alive!");
		}
		else CC_SendMessage(id, "You can't use this command more than &x04%i &x01times per round.", MAX_RESPAWNS);
	}
	else CC_SendMessage(id, "%L", id, "NO_ACC_COM");
	
	return PLUGIN_HANDLED;
}

public OnRoundStart()
	arrayset(g_iRespawns, 0, sizeof(g_iRespawns));

public OnPlayerSpawn(id)
{
	if(!is_user_alive(id))
		return;

	if(!is_user_vip(id))
	{
		set_user_health(id, PLAYER_HEALTH);
		return;
	}

	set_user_health(id, VIP_HEALTH);
	cs_set_user_armor(id, VIP_ARMOR, CS_ARMOR_VESTHELM);

	give_item(id, "weapon_hegrenade");
	give_item(id, "weapon_flashbang");

	set_user_rendering(id, kRenderFxGlowShell, GLOW_COLOR, kRenderNormal, GLOW_BRIGHTNESS)

	if(cs_get_user_team(id) == CS_TEAM_T)
		cs_set_weapon_ammo(give_item(id, "weapon_deagle"), 1);
}

public OnScoreAttrib(iMsgId, iDest, iReceiver)
{
	if(is_user_vip(get_msg_arg_int(SCOREATTRIB_ARG_PLAYERID)))
		set_msg_arg_int(SCOREATTRIB_ARG_FLAGS, ARG_BYTE, SCOREATTRIB_FLAG_VIP);
}

bool:is_user_vip(id)
	return !!(get_user_flags(id) & VIP_FLAG);