Изработка на плъгин - money rewards

В този раздел можете да подавате всякакви заявки за намиране, изработка или преработка на плъгини/модове.
Аватар
SkandaU
Извън линия
Потребител
Потребител
Мнения: 213
Регистриран на: 09 Яну 2017, 12:37
Се отблагодари: 45 пъти
Получена благодарност: 22 пъти

Изработка на плъгин - money rewards

Мнение от SkandaU » 04 Юли 2018, 23:38

Здравейте, трябва ми плъгин който при следните минути да дава пари:

5 минути = 1500$ - user | 3000$ - vip
10 минути = 3000$ - user | 6000$ - vip
15 минути = 5500$ - user | 11000$ - vip
30 минути = 8000$ - user | 16000$ - vip
Изображение

Аватар
Huehue
Извън линия
Модератор
Модератор
Мнения: 352
Регистриран на: 16 Яну 2017, 23:42
Местоположение: София
Се отблагодари: 7 пъти
Получена благодарност: 171 пъти
Обратна връзка:

Изработка на плъгин - money rewards

Мнение от Huehue » 05 Юли 2018, 11:27

Можеш да си добавяш колкото искаш времена.
За промяна на флага >>

Код за потвърждение: Избери целия код

#define VIP_ACCESS <тук кой флага да е>

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <engine>
#include <cstrike>

#tryinclude <cromchat>

#if !defined MAX_PLAYERS
#define MAX_PLAYERS 32
#endif

new g_iEntity
new g_iConnectTime[MAX_PLAYERS + 1]

#define VIP_ACCESS ADMIN_LEVEL_A

enum _:eData
{
	SECONDS,
	MONEY_AWARD_USER,
	MONEY_AWARD_VIP
}
new const g_iData[][eData] =
{
	/* TIME IN SECONDS 		MONEY FOR USER 		MONEY FOR VIP*/
	{ 	300, 					1500, 				3000 			},
	{ 	600, 					3000, 				6000 			},
	{ 	900, 					5500, 				11000 			},
	{ 	1800, 					8000, 				16000 			},
}

public plugin_init()
{
	register_plugin("PlayTime Money Awards", "1.0", "Huehue @ AMXX-BG.INFO")

	g_iEntity = create_entity("info_target")
	entity_set_string(g_iEntity , EV_SZ_classname , "ThinkingEnt")
	register_think("ThinkingEnt" , "EntityThink")
	
	entity_set_float(g_iEntity , EV_FL_nextthink , (get_gametime() + 1.0))

	#if defined _cromchat_included
	CC_SetPrefix("&x04[PlayTime]&x01")
	#endif
}

public client_putinserver(id)
{
	g_iConnectTime[id] = get_systime()
}

public EntityThink(iEntity)
{
	new iCurrentTime = get_systime()
	new iPlayers[32], iNum
	
	get_players(iPlayers , iNum)
	
	for (new i = 0, id; i < iNum; i++)
	{
		id = iPlayers[i]
		
		for (new x = 0, iReward, iConvertedTime; x < sizeof g_iData; x++)
		{
			if ((iCurrentTime - g_iConnectTime[id]) == g_iData[x][SECONDS])
			{
				iReward = is_user_vip(id) ? g_iData[x][MONEY_AWARD_VIP] : g_iData[x][MONEY_AWARD_USER]
				iConvertedTime = (g_iData[x][SECONDS] / 60) % 60
				cs_set_user_money(id, cs_get_user_money(id) + iReward)
				#if defined _cromchat_included
				CC_SendMatched(id, CC_COLOR_GREY, "You have played in the server for &x03%i minutes&x01 and you get for this &x04%i$", iConvertedTime, iReward)
				#else
				client_print(id, print_chat, "* You have played in the server for %i minutes and you get for this %i$", iConvertedTime, iReward)
				#endif
			}
		}
	}
	entity_set_float(g_iEntity, EV_FL_nextthink, (get_gametime() + 1.0))
}

bool:is_user_vip(const id)
	return bool:(get_user_flags(id) & VIP_ACCESS)
LOYAL TO THE OATH OF OMERTА̀

Зад монитора мъжкари, това не го разбирам..
На живо сте мишкари, това го гарантирам!
Седиш на 30 метра от мен като препариран!
Ако има нещо брат, номерът ми е блокиран..

My GitHub Profile
GitHub

My AMXX Includes Collection
AMXX Include Libraries

My Steam Profile (from SteamDB)
  • Value: 4179€
  • Games owned: 1855
  • Games played: 754 (40%)
  • Hours on record: 4,994.9h

Аватар
SkandaU
Извън линия
Потребител
Потребител
Мнения: 213
Регистриран на: 09 Яну 2017, 12:37
Се отблагодари: 45 пъти
Получена благодарност: 22 пъти

Изработка на плъгин - money rewards

Мнение от SkandaU » 05 Юли 2018, 13:14

Супер, благодаря ти! Лок.
Изображение

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Заявки за плъгини”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 13 госта