Търся няколко плъгина за hns

[End Of Life]

Търся някакъв анти-фраг ако може да не е този който забавя играча, а съм виждал плъгин в който няколко секунди неможеш да го убиеш, колкото и да се пробваш??

Търся и плъгин-а SHOWKEYS, намерих един който не работеше, такаче ако може някой работещ.

И искам да попитам защо като хвърля FLASH не виждам хората от противниковия отбор?

[DoPe ;]]]

Пробвай това може да ти помогне...

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>
#include <colorchat>
#include <fakemeta>
#include <fun>

#define PLUGIN "AntiFrager HNS"
#define VERSION "1.0"
#define AUTHOR "unknown"

new bool:tt_stop[33]
new cvar_times
new Float:times

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    RegisterHam(Ham_TakeDamage, "player", "player_damage")
    register_forward(FM_PlayerPreThink,"fw_playerprethink",0);
    cvar_times = register_cvar("hs_stop_time","3.0")
    
}
public player_damage(victim, ent, attacker, Float:damage, bits)
{
    if(!is_user_connected(victim) || !is_user_connected(attacker) || victim == attacker)
        return HAM_IGNORED
        
    new name[32]
    get_user_name(attacker,name,31)
    times = get_pcvar_float(cvar_times)
        
    if(get_user_team(attacker) == 2 && get_user_team(victim) == 1)
    {
        if(!tt_stop[attacker])
        {
        tt_stop[attacker] = true
        ColorChat(attacker, RED,"^3[Anti-frag]^1You are frozen on %3.1f sec,^4so T can escape",times)
        ColorChat(victim, RED,"^3[Anti-frag]^1You are cut off ^4%s",name)
        set_task(times,"cmdOffStop",attacker)
        }
    }
    return HAM_IGNORED
}
public client_disconnect(id)
{
remove_task(id)
}
public cmdOffStop(id)
{
tt_stop[id] = false    
}
public fw_playerprethink(id)
{
if(tt_stop[id])
engfunc(EngFunc_SetClientMaxspeed,id,0.00001);
else
engfunc(EngFunc_SetClientMaxspeed,id,250.0);
return FMRES_IGNORED;
}

[OciXCrom]

https://forums.alliedmods.net/showthrea ... 7?p=484967
https://forums.alliedmods.net/showthread.php?t=59932

Търся някакъв анти-фраг ако може да не е този който забавя играча, а съм виждал плъгин в който няколко секунди неможеш да го убиеш, колкото и да се пробваш??

С цел да те разберат всички, а не само тези, които са играли HNS (или само ти), ще е хубаво да обясниш за какво става дума.

[End Of Life]

Плъгин който забранява фраг-а, демек - за да убиеш някого с ножа са ти нужни 2-удара, а този плъгин прави така че сякаш за 3 секунди си безсмъртен и неможе да те заколи, незнам просто как да го обясня по друг начин, пича по-горе явно ме е разбрал, но и този код не прави това което искам като ефект, не искам да го забавя а да го slow-ва, да го забавя един вид.

[OciXCrom]

не искам да го забавя а да го slow-ва, да го забавя един вид

Чуваш ли се?

Как така си безсмъртен за 3 секунди? Кога ставаш безсмъртен? Обясни по-добре.

[JustyleR]

Когато искаш да убиеш някого, ти трябва да го удариш 2 пъти в тялото или 1 път в главата, в Hide N Seek мода се е изградило едно правило за фраг, тоест когато удариш някого 1 път, играчът когото си ударил в повечето случаи (ако няма плъгин) му се забавя скороста и много лесно могат да го ударят пак, човека търси плъгин, който когато ударят играч (Terrorist), да му дава godmode за около 2-3сек. За да може да избяга от човека който го гони.

Надявам се, че добре описах какво точно означава термина "фраг" в HNS.

[OciXCrom]

Когато някой те удари, няма да може да те ударят в следващите 3 секунди:

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <hamsandwich>

#define HIT_DELAY 3
new g_iLastHit[33]

public plugin_init() 
{
    register_plugin("HNS Hit Delay", "1.0", "OciXCrom @ amxx-bg.info/forum")
    RegisterHam(Ham_TraceAttack, "player", "PrePlayerAttack")
    RegisterHam(Ham_TakeDamage, "player", "OnPlayerTakeDamage", 1)
}

public client_putinserver(id)
    g_iLastHit[id] = 0

public PrePlayerAttack(iVictim, iAttacker)
{
    if(!is_user_connected(iAttacker) || iVictim == iAttacker || get_user_team(iVictim) != 1)
        return HAM_IGNORED
        
    return (get_systime() - g_iLastHit[iVictim] < HIT_DELAY) ? HAM_SUPERCEDE : HAM_IGNORED
}

public OnPlayerTakeDamage(iVictim, iInflictor, iAttacker)
{
    if(is_user_connected(iAttacker) && get_user_team(iVictim) == 1)
        g_iLastHit[iVictim] = get_systime()
} 

[End Of Life]

Може да заключвате, много благодаря, стана всичко което исках.