Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Въведение в PAWN скриптинга и поддръжка за същия.
Аватар
mi0
Извън линия
AMXX Скриптър
AMXX Скриптър
Мнения: 534
Регистриран на: 09 Дек 2016, 22:02
Се отблагодари: 97 пъти
Получена благодарност: 120 пъти
Обратна връзка:

Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Мнение от mi0 » 31 Юли 2019, 06:25

Няма абсолютно никаква причина да ти дава тези грешки. Сигурен ли си, че си компилирал точно кода отгоре??? Проблема беше, че играча по някой път беше id 0, което е сървъра, в момента има проверка и няма как да ти даде такъв Error(Invalid Player при положение, че is_user_connected проверява точно дали е Valid)
aka kurdokoleno
Catch Mod - 87.121.112.232:27021

Аватар
gattuso1991
Извън линия
Потребител
Потребител
Мнения: 8
Регистриран на: 22 Яну 2018, 15:54

Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Мнение от gattuso1991 » 31 Юли 2019, 07:48

С коя версия на Zombie Plague си?

Аватар
mi0
Извън линия
AMXX Скриптър
AMXX Скриптър
Мнения: 534
Регистриран на: 09 Дек 2016, 22:02
Се отблагодари: 97 пъти
Получена благодарност: 120 пъти
Обратна връзка:

Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Мнение от mi0 » 31 Юли 2019, 09:02

gattuso1991 написа: 31 Юли 2019, 07:48 С коя версия на Zombie Plague си?
Няма нищо общо с версията.
aka kurdokoleno
Catch Mod - 87.121.112.232:27021

Аватар
TheRedShoko
Извън линия
Модератор
Модератор
Мнения: 1016
Регистриран на: 06 Окт 2016, 07:42
Местоположение: Бургас
Се отблагодари: 5 пъти
Получена благодарност: 84 пъти

Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Мнение от TheRedShoko » 31 Юли 2019, 12:10

Проблемът идва, когато играчът е първо зомби. Тогава forward-a се извиква с id на инфектиращия = 0. Когато проверява дали инфектиращия е от дадения зомби клас, на натива се изпраща 0, което е невалидно Id за играч и съответно хвърля грешка. @mi0 се е опитал да го оправи, но е объркал проверката. Той проверява дали играчът е валиден и ако е - бие return. Просто трябва да се вземе отрицанието на is_user_connected и всичко ще е ток и жица. С този код няма да ти хвърля грешка, поне не тази същата.

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <zombieplague>
#include <fakemeta>
#include <hamsandwich>
#include <engine>

#define PLUGIN "[ZP] Class Smoker"
#define VERSION "1.3"
#define AUTHOR "4eRT"

//Main Class, modelT & Sprite Beam
new g_zclass_smoker, g_Line
new const generic_models[][] = { "models/player/zombie_smoker/zombie_smokerT.mdl" }
//Sounds
new g_sndMiss[] = "zombie_plague/Smoker_TongueHit_miss.wav"
new g_sndDrag[] = "zombie_plague/Smoker_TongueHit_drag.wav"
//Some vars
new g_hooked[33], g_hooksLeft[33], g_unable2move[33], g_ovr_dmg[33]
new Float:g_lastHook[33]
new bool: g_bind_use[33] = false, bool: g_bind_or_not[33] = false, bool: g_drag_i[33] = false
//Cvars
new cvar_maxdrags, cvar_dragspeed, cvar_cooldown, cvar_dmg2stop, cvar_mates, cvar_extrahook, cvar_unb2move, cvar_nemesis, cvar_survivor
//Menu keys
new keys = MENU_KEY_1|MENU_KEY_2|MENU_KEY_3
//Smoker Atributes
new const zclass_name[] = { "Smoker" }
new const zclass_info[] = { "Can drag players" }
new const zclass_model[] = { "zombie_source" }
new const zclass_clawmodel[] = { "v_knife_zombie.mdl" }
const zclass_health = 1400
const zclass_speed = 190
const Float:zclass_gravity = 1.0
const Float:zclass_knockback = 1.0

public plugin_init()
{
	cvar_dragspeed = register_cvar("zp_smoker_dragspeed", "170")
	cvar_maxdrags = register_cvar("zp_smoker_maxdrags", "7")
	cvar_cooldown = register_cvar("zp_smoker_cooldown", "5")
	cvar_dmg2stop = register_cvar("zp_smoker_dmg2stop", "300")
	cvar_mates = register_cvar("zp_smoker_mates", "0")
	cvar_extrahook = register_cvar("zp_smoker_extrahook", "2")
	cvar_unb2move = register_cvar("zp_smoker_unable_move", "1")
	cvar_nemesis = register_cvar("zp_smoker_nemesis", "0")
	cvar_survivor = register_cvar("zp_smoker_survivor", "1")
	register_event("ResetHUD", "newSpawn", "b")
	register_event("DeathMsg", "smoker_death", "a")
	register_forward(FM_PlayerPreThink, "fw_PlayerPreThink")
	RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
	register_clcmd("+drag","drag_start", ADMIN_USER, "bind ^"key^" ^"+drag^"")
	register_clcmd("-drag","drag_end")
	register_menucmd(register_menuid("Do you want to bind V +drag?"), keys, "bind_v_key")
}
public plugin_precache()
{
	register_plugin(PLUGIN, VERSION, AUTHOR)
	g_zclass_smoker = zp_register_zombie_class(zclass_name, zclass_info, zclass_model, zclass_clawmodel, zclass_health, zclass_speed, zclass_gravity, zclass_knockback)
	precache_sound(g_sndDrag)
	precache_sound(g_sndMiss)
	g_Line = precache_model("sprites/zbeam4.spr")

	for (new i = 0; i < sizeof generic_models; i++)
	precache_model(generic_models[i])
}

public zp_user_infected_post(id, infector)
{
        if  (!is_user_connected(infector))
        {
                return
        }

	if ((zp_get_user_zombie_class(infector) == g_zclass_smoker) && (get_pcvar_num(cvar_extrahook) > 0))
	{
		g_hooksLeft[infector] = g_hooksLeft[infector] + get_pcvar_num(cvar_extrahook)
		set_hudmessage(255, 0, 0, -1.0, 0.45, 0, 0.0, 3.0, 0.01, 0.01, -1)
		show_hudmessage(infector, "+%d drag%s!", get_pcvar_num(cvar_extrahook), (get_pcvar_num(cvar_extrahook) < 2) ? "" : "s")
	}

	if (zp_get_user_zombie_class(id) == g_zclass_smoker)
	{
		g_hooksLeft[id] = get_pcvar_num(cvar_maxdrags)

		if (!g_bind_or_not[id])
		{
			new menu[192]
			format(menu, 191, "Do you want to bind V +drag?^n^n1. Yes^n2. No^n3. Drag on +USE")
			show_menu(id, keys, menu)
		}
	}
}

public newSpawn(id)
{
	if (g_hooked[id])
		drag_end(id)
}

public drag_start(id) // starts drag, checks if player is Smoker, checks cvars
{
	if (zp_get_user_zombie(id) && (zp_get_user_zombie_class(id) == g_zclass_smoker) && !g_drag_i[id]) {

		static Float:cdown
		cdown = get_pcvar_float(cvar_cooldown)

		if (!is_user_alive(id)) {
			client_print(id, print_chat, "[ZP] You can't drag if you are dead!")
			return PLUGIN_HANDLED
		}

		if (g_hooksLeft[id] <= 0) {
			client_print(id, print_chat, "[ZP] You can't drag anymore!")
			return PLUGIN_HANDLED
		}

		if (get_gametime() - g_lastHook[id] < cdown) {
			client_print(id, print_chat, "[ZP] Wait %.f0 sec. to drag again!", get_pcvar_float(cvar_cooldown) - (get_gametime() - g_lastHook[id]))
			return PLUGIN_HANDLED
		}

		new hooktarget, body
		get_user_aiming(id, hooktarget, body)

		if (zp_get_user_nemesis(id) && get_pcvar_num(cvar_nemesis) == 0) {
			client_print(id, print_chat, "[ZP] You can't drag if you are Nemesis!")
			return PLUGIN_HANDLED
		}

		if (is_user_alive(hooktarget)) {
			if (!zp_get_user_zombie(hooktarget))
				{
					if (zp_get_user_survivor(hooktarget) && get_pcvar_num(cvar_survivor) == 0) {
						client_print(id, print_chat, "[ZP] You can't drag Survivor!")
						return PLUGIN_HANDLED
					}

					g_hooked[id] = hooktarget
					emit_sound(hooktarget, CHAN_BODY, g_sndDrag, 1.0, ATTN_NORM, 0, PITCH_HIGH)
				}
			else
				{
					if (get_pcvar_num(cvar_mates) == 1)
					{
						g_hooked[id] = hooktarget
						emit_sound(hooktarget, CHAN_BODY, g_sndDrag, 1.0, ATTN_NORM, 0, PITCH_HIGH)
					}
					else
					{
						client_print(id, print_chat, "[ZP] You can't drag teammates!")
						return PLUGIN_HANDLED
					}
				}

			if (get_pcvar_float(cvar_dragspeed) <= 0.0)
				cvar_dragspeed = 1

			new parm[2]
			parm[0] = id
			parm[1] = hooktarget

			set_task(0.1, "smoker_reelin", id, parm, 2, "b")
			harpoon_target(parm)

			g_hooksLeft[id]--
			client_print(id, print_chat, "[ZP] You can drag player to youself %d time%s", g_hooksLeft[id], (g_hooksLeft[id] < 2) ? "" : "s")
			g_drag_i[id] = true

			if(get_pcvar_num(cvar_unb2move) == 1)
				g_unable2move[hooktarget] = true

			if(get_pcvar_num(cvar_unb2move) == 2)
				g_unable2move[id] = true

			if(get_pcvar_num(cvar_unb2move) == 3)
			{
				g_unable2move[hooktarget] = true
				g_unable2move[id] = true
			}
		} else {
			g_hooked[id] = 33
			noTarget(id)
			emit_sound(hooktarget, CHAN_BODY, g_sndMiss, 1.0, ATTN_NORM, 0, PITCH_HIGH)
			g_drag_i[id] = true
			g_hooksLeft[id]--
			client_print(id, print_chat, "[ZP] You can drag player to youself %d time%s", g_hooksLeft[id], (g_hooksLeft[id] < 2) ? "" : "s")
		}
	}
	else
		return PLUGIN_HANDLED

	return PLUGIN_CONTINUE
}

public smoker_reelin(parm[]) // dragging player to smoker
{
	new id = parm[0]
	new victim = parm[1]

	if (!g_hooked[id] || !is_user_alive(victim))
	{
		drag_end(id)
		return
	}

	new Float:fl_Velocity[3]
	new idOrigin[3], vicOrigin[3]

	get_user_origin(victim, vicOrigin)
	get_user_origin(id, idOrigin)

	new distance = get_distance(idOrigin, vicOrigin)

	if (distance > 1) {
		new Float:fl_Time = distance / get_pcvar_float(cvar_dragspeed)

		fl_Velocity[0] = (idOrigin[0] - vicOrigin[0]) / fl_Time
		fl_Velocity[1] = (idOrigin[1] - vicOrigin[1]) / fl_Time
		fl_Velocity[2] = (idOrigin[2] - vicOrigin[2]) / fl_Time
	} else {
		fl_Velocity[0] = 0.0
		fl_Velocity[1] = 0.0
		fl_Velocity[2] = 0.0
	}

	entity_set_vector(victim, EV_VEC_velocity, fl_Velocity) //<- rewritten. now uses engine
}

public drag_end(id) // drags end function
{
	g_hooked[id] = 0
	beam_remove(id)
	remove_task(id)

	if (g_drag_i[id])
		g_lastHook[id] = get_gametime()

	g_drag_i[id] = false
	g_unable2move[id] = false
}

public smoker_death() // if smoker dies drag off
{
	new id = read_data(2)

	beam_remove(id)

	if (g_hooked[id])
		drag_end(id)
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage) // if take damage drag off
{
	if (is_user_alive(attacker) && (get_pcvar_num(cvar_dmg2stop) > 0))
	{
		g_ovr_dmg[victim] = g_ovr_dmg[victim] + floatround(damage)
		if (g_ovr_dmg[victim] >= get_pcvar_num(cvar_dmg2stop))
		{
			g_ovr_dmg[victim] = 0
			drag_end(victim)
			return HAM_IGNORED;
		}
	}

	return HAM_IGNORED;
}

public fw_PlayerPreThink(id)
{
	if (!is_user_alive(id))
		return FMRES_IGNORED

	new button = get_user_button(id)
	new oldbutton = get_user_oldbutton(id)

	if (g_bind_use[id] && zp_get_user_zombie(id) && (zp_get_user_zombie_class(id) == g_zclass_smoker))
	{
		if (!(oldbutton & IN_USE) && (button & IN_USE))
			drag_start(id)

		if ((oldbutton & IN_USE) && !(button & IN_USE))
			drag_end(id)
	}

	if (!g_drag_i[id]) {
		g_unable2move[id] = false
	}

	if (g_unable2move[id] && get_pcvar_num(cvar_unb2move) > 0)
	{
		set_pev(id, pev_maxspeed, 1.0)
	}

	return PLUGIN_CONTINUE
}

public client_disconnect(id) // if client disconnects drag off
{
	if (id <= 0 || id > 32)
		return

	if (g_hooked[id])
		drag_end(id)

	if(g_unable2move[id])
		g_unable2move[id] = false
}

public harpoon_target(parm[]) // set beam (ex. tongue:) if target is player
{
	new id = parm[0]
	new hooktarget = parm[1]

	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(8)	// TE_BEAMENTS
	write_short(id)
	write_short(hooktarget)
	write_short(g_Line)	// sprite index
	write_byte(0)	// start frame
	write_byte(0)	// framerate
	write_byte(200)	// life
	write_byte(8)	// width
	write_byte(1)	// noise
	write_byte(155)	// r, g, b
	write_byte(155)	// r, g, b
	write_byte(55)	// r, g, b
	write_byte(90)	// brightness
	write_byte(10)	// speed
	message_end()
}

public bind_v_key(id, keys)
{
	g_bind_or_not[id] = true
	switch(keys)
	{
		case 0:
			client_cmd(id, "bind v ^"+drag^"")

		case 1:
			client_print(id, print_chat, "[ZP] To drag player to youself (bind ^'^'key^'^' ^'^'+drag^'^') hold binded key")

		case 2:
			g_bind_use[id] = true

		default:
			g_bind_or_not[id] = false
	}

	return PLUGIN_HANDLED
}

public noTarget(id) // set beam if target isn't player
{
	new endorigin[3]

	get_user_origin(id, endorigin, 3)

	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte( TE_BEAMENTPOINT ); // TE_BEAMENTPOINT
	write_short(id)
	write_coord(endorigin[0])
	write_coord(endorigin[1])
	write_coord(endorigin[2])
	write_short(g_Line) // sprite index
	write_byte(0)	// start frame
	write_byte(0)	// framerate
	write_byte(200)	// life
	write_byte(8)	// width
	write_byte(1)	// noise
	write_byte(155)	// r, g, b
	write_byte(155)	// r, g, b
	write_byte(55)	// r, g, b
	write_byte(75)	// brightness
	write_byte(0)	// speed
	message_end()
}

public beam_remove(id) // remove beam
{
	message_begin(MSG_BROADCAST, SVC_TEMPENTITY)
	write_byte(99)	//TE_KILLBEAM
	write_short(id)	//entity
	message_end()
}

Аватар
lurku
Извън линия
Потребител
Потребител
Мнения: 45
Регистриран на: 15 Юни 2019, 22:07
Се отблагодари: 6 пъти
Получена благодарност: 1 път
Обратна връзка:

Проблем с [Class] Zombie Smoker ? Грешка в конзолата [Помощ]

Мнение от lurku » 31 Юли 2019, 19:25

Да вече не дава грешка благодаря ви :)

Заключено
  • Подобни теми
    Отговори
    Преглеждания
     Последно мнение

Обратно към “Скриптиране”

Кой е на линия

Потребители разглеждащи този форум: 0 регистрирани и 9 госта