Страница 1 от 8

CSHOP Extra Item: Golden AK47

Публикувано на: 10 Яну 2017, 15:55
от OciXCrom
CSHOP Extra Item: Golden AK47
Изображение

Описание
  • Плъгинът добавя допълнителен предмет в Custom Shop - Golden AK47. Калашникът има златен модел, увеличена щета и златни патрони.
Изисквания
  • Custom Shop версия 3.0 или по-нова.
Инсталация
  • Имайте предвид, че плъгинът няма да работи без базовия плъгин за Custom Shop (custom_shop.amxx).
  • Файлът cshop_goldenak.amxx се добавя в папката plugins.
  • Файлът cshop_goldenak.sma се добавя в папката scripting.
  • Файловете v_goldenak.mdl и p_goldenak.mdl се добавят в папката models/custom_shop.
  • В configs/plugins-cshop.ini добавяте cshop_goldenak.amxx.
Настройка по подразбиране
  • Настройките изискват редакция на файла cshop_goldenak.sma.

    Код за потвърждение: Избери целия код

    additem ITEM_GOLDENAK
    #define GOLDENAK_NAME "Golden AK47"
    #define GOLDENAK_PRICE 16000
    #define GOLDENAK_LIMIT 1
    #define GOLDENAK_SOUND "weapons/gauss2.wav"
    #define GOLDENAK_VMODEL "models/custom_shop/v_goldenak.mdl"
    #define GOLDENAK_PMODEL "models/custom_shop/p_goldenak.mdl"
    #define GOLDENAK_WEAPON_STR "weapon_ak47"
    #define GOLDENAK_WEAPON_CSW CSW_AK47
    #define GOLDENAK_DAMAGE 5
    #define GOLDENAK_AMMO 500
    new bool:g_blGoldenAK[33]
    
    // Comment this line to disable the bullets.
    #define USE_BULLETS
    
    #if defined USE_BULLETS
        // You can add a shoot sound in this line, after you remove the comment.
        //#define BULLET_SOUND "weapons/ak47-1.wav"
        
        #define BULLET_MODEL "sprites/dot.spr"
        #define BULLET_STARTFRAME 1
        #define BULLET_FRAMERATE 5
        #define BULLET_LIFE 2
        #define BULLET_WIDTH 10
        #define BULLET_NOISE 0
        #define BULLET_COLOR_RED 255
        #define BULLET_COLOR_GREEN 215
        #define BULLET_COLOR_BLUE 0
        #define BULLET_BRIGHTNESS 200
        #define BULLET_SPEED 150
        new g_iGoldenBullet
    #endif
    
    #define DEFAULT_VMODEL "models/v_ak47.mdl"
    #define DEFAULT_PMODEL "models/p_ak47.mdl"        
Допълнителна информация и линк за теглене

Изображение

Re: Custom Shop Addon: Golden AK47

Публикувано на: 24 Фев 2017, 17:39
от MF1
не мога да компилирам -

Код за потвърждение: Избери целия код

111.txt(1) : error 010: invalid function or declaration
111.txt(36) : warning 203: symbol is never used: "g_blGoldenAK"
111.txt(36) : warning 203: symbol is never used: "g_iGoldenBullet"
111.txt(36) : error 013: no entry point (no public functions)
Извинявам се, не бях добавил .inc файловете на шоп-а

Re: Custom Shop Addon: Golden AK47

Публикувано на: 25 Фев 2017, 10:51
от MF1
Здравейте ! Как мога да направя така, че когато се купи предмета - да хвърля другия автоматично ?
Тоест имам 1 AK, купувам този и първия да ми се махне и да остана само с Golden-a

Re: Custom Shop Addon: Golden AK47

Публикувано на: 25 Фев 2017, 14:35
от OciXCrom
Наистина не разбрах къде видя, че получаваш 2 различни, нито пък как е възможно да имаш два калашника наведнъж.

Re: Custom Shop Addon: Golden AK47

Публикувано на: 25 Фев 2017, 14:57
от MF1
моя грешка... говоря когато имаш друго оръжие различно от калашник.

Re: Custom Shop Addon: Golden AK47

Публикувано на: 25 Фев 2017, 16:59
от OciXCrom

Код за потвърждение: Избери целия код

#include <amxmodx>
#include <cstrike>
#include <customshop>
#include <fakemeta>
#include <fun>
#include <hamsandwich>
#include <stripweapons>

#define PLUGIN_VERSION "1.2"

additem ITEM_GOLDENAK
#define GOLDENAK_ID "goldenak"
#define GOLDENAK_NAME "Golden AK47"
#define GOLDENAK_PRICE 16000
#define GOLDENAK_LIMIT 1
#define GOLDENAK_SOUND "weapons/gauss2.wav"
#define GOLDENAK_VMODEL "models/custom_shop/v_goldenak.mdl"
#define GOLDENAK_PMODEL "models/custom_shop/p_goldenak.mdl"
#define GOLDENAK_WEAPON_STR "weapon_ak47"
#define GOLDENAK_WEAPON_CSW CSW_AK47
#define GOLDENAK_DAMAGE 5
#define GOLDENAK_AMMO 500
new bool:g_blGoldenAK[33]

// Comment this line to disable the bullets.
#define USE_BULLETS

#if defined USE_BULLETS
    // You can add a shoot sound in this line, after you remove the comment.
    //#define BULLET_SOUND "weapons/ak47-1.wav"
    
    #define BULLET_MODEL "sprites/dot.spr"
    #define BULLET_STARTFRAME 1
    #define BULLET_FRAMERATE 5
    #define BULLET_LIFE 2
    #define BULLET_WIDTH 10
    #define BULLET_NOISE 0
    #define BULLET_COLOR_RED 255
    #define BULLET_COLOR_GREEN 215
    #define BULLET_COLOR_BLUE 0
    #define BULLET_BRIGHTNESS 200
    #define BULLET_SPEED 150
    new g_iGoldenBullet
#endif

#define DEFAULT_VMODEL "models/v_ak47.mdl"
#define DEFAULT_PMODEL "models/p_ak47.mdl"

public plugin_init()
{
    register_plugin("Custom Shop: Golden AK47", PLUGIN_VERSION, "OciXCrom")
    RegisterHam(Ham_TakeDamage, "player", "eventTakeDamage")
    register_event("CurWeapon", "goldenModel", "be", "1=1")
    
    #if defined USE_BULLETS
        RegisterHam(Ham_Weapon_PrimaryAttack, GOLDENAK_WEAPON_STR, "eventPrimaryAttack", 1)
    #endif
}

public plugin_precache()
{
    ITEM_GOLDENAK = cshopRegisterItem(GOLDENAK_ID, GOLDENAK_NAME, GOLDENAK_PRICE, GOLDENAK_LIMIT)
    precache_model(GOLDENAK_VMODEL)
    precache_model(GOLDENAK_PMODEL)
    
    #if defined USE_BULLETS
        g_iGoldenBullet = precache_model(BULLET_MODEL)
    #endif
    
    #if defined BULLET_SOUND
        precache_sound(BULLET_SOUND)
    #endif
}

public cshopItemBought(id, iItem)
    if(iItem == ITEM_GOLDENAK)             { g_blGoldenAK[id] = true; StripWeapons(id, Primary); give_item(id, GOLDENAK_WEAPON_STR); cs_set_user_bpammo(id, GOLDENAK_WEAPON_CSW, GOLDENAK_AMMO); goldenModel(id); }
    
public cshopItemRemoved(id, iItem)
    if(iItem == ITEM_GOLDENAK)             { g_blGoldenAK[id] = false; set_default_model(id); }
    
public eventTakeDamage(iVictim, iInflictor, iAttacker, Float:flDamage, iDamageBits)
    if(is_user_alive(iAttacker) && iAttacker != iVictim)
        if(g_blGoldenAK[iAttacker])
            SetHamParamFloat(4, flDamage * GOLDENAK_DAMAGE)
            
#if defined USE_BULLETS            
    public eventPrimaryAttack(iWeapon)
    {
        new id = pev(iWeapon, pev_owner)
        
        if(!g_blGoldenAK[id])
            return
            
        new iClip, iAmmo
        new iWeapon = get_user_weapon(id, iClip, iAmmo)
        
        if(!iClip || iWeapon != GOLDENAK_WEAPON_CSW)
            return
        
        #if defined BULLET_SOUND
            player_emitsound(id, BULLET_SOUND)
        #endif
        
        new iVec1[3], iVec2[3]
        get_user_origin(id, iVec1, 1)
        get_user_origin(id, iVec2, 3)
        message_begin(MSG_BROADCAST,SVC_TEMPENTITY)
        write_byte(TE_BEAMPOINTS)
        write_coord(iVec1[0])
        write_coord(iVec1[1])
        write_coord(iVec1[2])
        write_coord(iVec2[0])
        write_coord(iVec2[1])
        write_coord(iVec2[2])
        write_short(g_iGoldenBullet)
        write_byte(BULLET_STARTFRAME)
        write_byte(BULLET_FRAMERATE)
        write_byte(BULLET_LIFE)
        write_byte(BULLET_WIDTH)
        write_byte(BULLET_NOISE)
        write_byte(BULLET_COLOR_RED)
        write_byte(BULLET_COLOR_GREEN)
        write_byte(BULLET_COLOR_BLUE)
        write_byte(BULLET_BRIGHTNESS)
        write_byte(BULLET_SPEED)
        message_end()
    }
#endif

public goldenModel(id)
{
    if(get_user_weapon(id) == GOLDENAK_WEAPON_CSW && g_blGoldenAK[id])
    {
        set_pev(id, pev_viewmodel2, GOLDENAK_VMODEL)
        set_pev(id, pev_weaponmodel2, GOLDENAK_PMODEL)
    }
}

set_default_model(id)
{
    if(get_user_weapon(id) == GOLDENAK_WEAPON_CSW)
    {
        set_pev(id, pev_viewmodel2, DEFAULT_VMODEL)
        set_pev(id, pev_weaponmodel2, DEFAULT_PMODEL)
    }
}

#if defined BULLET_SOUND
    player_emitsound(id, szSound[])
        emit_sound(id, CHAN_WEAPON, szSound, 1.0, ATTN_NORM, 0, PITCH_HIGH)
#endif 

Re: Custom Shop Addon: Golden AK47

Публикувано на: 01 Мар 2017, 21:31
от SmallLoll
А може ли да се добавят освен голден ак голден м4а1 и голден авп

Re: Custom Shop Addon: Golden AK47

Публикувано на: 01 Мар 2017, 21:48
от OciXCrom
Просто копирай плъгина с друго име и замени настройките (редовете започващи с #define), тоест смени калашника с оръжието, което искаш.

#define GOLDENAK_ID "goldenak" трябва да стане #define GOLDENAK_ID "goldenm4a1"
#define GOLDENAK_NAME "Golden AK47" трябва да стане #define GOLDENAK_NAME "Golden M4A1"
#define GOLDENAK_WEAPON_STR "weapon_ak47" трябва да стане #define GOLDENAK_WEAPON_STR "weapon_m4a1"

... и така нататък... Провери всички #define редове и където има AK47, замени го с M4A1 или AWP.
Опитай сам да го направиш и предостави това, което си направил, ако не се получава.

ПС - достатъчно е да промениш само стойността на променливите. Имената им може да останат непроменени - GOLDENAK_ID, GOLDENAK_NAME и тн...

Re: Custom Shop Addon: Golden AK47

Публикувано на: 01 Мар 2017, 23:13
от SmallLoll
Мисълта ми беше ако може да се направи Custum Shop Addon с включени в него GoldenAk47 GoldenM4A1 и GoldenAwp

Re: Custom Shop Addon: Golden AK47

Публикувано на: 01 Мар 2017, 23:46
от OciXCrom
Точно това казах и аз. Можеш да копираш плъгина и да направиш два други за различните оръжия. Няма смисъл да се наблъска всичко в един плъгин.